CopyMoveFile ( ~OriginalFilePath ; ~EndFilePath ; ~MacServerPath ; ~PCServerPath ; ~MoveOrCopy )

Move or Copy a file in Finder or Explorer using CMD or Terminal commands

Average rating: 5.0 (3 votes) Log in to vote

Reeve Schragger
White Studio
http://www.whitestudio.net.au

Sample input:

CopyMoveFile (
"X:/MainFolder/Subfolder/File.pdf" ;
"X:/MainFolder/NewFolder/FileCopied.pdf" ;
"/Volumes/DataServer/" ;
"X:/" ;
"C" ;
)

Sample output:

do shell script "cp " & quoted form of "/Volumes/DataServer/MainFolder/Subfolder/File.pdf" & " " & quoted form of "/Volumes/DataServer/MainFolder/NewFolder/FileCopied.pdf"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * ==================================================================
 * CopyMoveFile ( ~OriginalFilePath ; ~EndFilePath ; ~MacServerPath ; ~PCServerPath ; ~MoveOrCopy )
 *
 * PARAMETERS:
 *            ~OriginalFilePath (Text)	Current file ( § Must include file name or it will try to copy/move whole folder)
 *            ~EndFilePath	(Text)	Where to put file, file name optional, if used can make file name change
 *             						If file name not given will use original file name
 *
 *            ~MacServerPath	(Text)Opt	Optional, if a cross platform solution, need to put the start of the
 *            ~PCServerPath	(Text)Opt	Filepaths as they occur on both systems. Both of these paths 
 *							should end before the SAME directory e.g. both stop before "/Client"
 *
 *							Mac	/volumes/Data/	(for /volumes/Data/Client/Coca-Cola/fileA.txt)
 *							PC	R:/ 				(for R:/Client/Coca-Cola/fileA.txt )
 *
 *							If cross platform is no issue, simply put 0 in each (or Null)
 *
 *            ~MoveOrCopy	(Text)	Enter "M" or "Move" or "C" or "Copy". 
 *							Failure/Incorrect will default to COPY command
 *
* RETURNS:
 *            (Text) Applescript for Mac or Terminal Command for PC
 *           
 * DEPENDENCIES:
 *            none - Checks for OS
 *            I use Set Variable step to create script, then use that variable in BOTH an Applescript and Send Event step
 *            Filemaker paths will not work natively. I use a separate CF to convert them if required
 *            It will not work in iOS or Android but as it creates a CMD or Applescript result it "could" be passed???
 * PURPOSE:
 *            Use this function to move files around your finder/explorer. It is designed to allow for usage on
 *            both Macs and PCs with paths created on either 
 *            Note if you MOVE files, the original file will DISSAPPEAR
 *            If you need to retain original file use the COPY command
 *            Can be used to simply rename files
 *
 * NOTES:
 *            § For simplicity sake I have not included the terminal/command options so this does a 
 *             very "plain" copy. I cannot predict what will happen if directories etc are copied, (it certainly won't
 *             work properly on Mac) you might need to re-program to allow if you need it. I suggest going to
 *             https://ss64.com as it has excellent resources with all the relevant options displayed
 * REVISIONS:
 *            27/7/2017 - Initial release
 *            © Reeve Schragger 2017 
 * ==================================================================
 *
 */

Let  (  [

	//- - -Normalise Paths
	~OriginalFilePath = 	Substitute ( ~OriginalFilePath 	;  [ "\\" ; "/" ] ) ;
	~EndFilePath = 		Substitute ( ~EndFilePath		;  [ "\\" ; "/" ] ) ;

	//- - -Check Operating System
	~OS= Case (
		Abs ( Get ( SystemPlatform ) ) = 1 ; "Mac" ;
		Abs ( Get ( SystemPlatform ) ) = 2 ; "PC" ;
		"Other" ) ;
	~Command = Left ( Upper ( ~MoveOrCopy ) ; 1 ) ;
	~Command = If ( ~Command = "M" or ~Command = "C" ; ~Command ; "C" ) ; 

	// - - - Make Correct paths for solution
	~Path1 = Case (
		~OS = "Mac"	; Substitute ( ~OriginalFilePath ; [ ~PCServerPath ; ~MacServerPath ] ; [ "\\" ; "/" ] ) ;
		~OS = "PC"	; Substitute ( ~OriginalFilePath ; [ ~MacServerPath ; ~PCServerPath ] ; [ "/" ; "\\" ] ) ;
		"") ;

	~Path2 = Case (
		~OS = "Mac"	; Substitute ( ~EndFilePath ; [ ~PCServerPath ; ~MacServerPath ] ; [ "\\" ; "/" ]  ) ;
		~OS = "PC"	; Substitute ( ~EndFilePath ; [ ~MacServerPath ; ~PCServerPath ] ; [ "/" ; "\\" ] ) ;
		"") ;

	//- - - Make Script text
	~MovePCScript =	"cmd /c MOVE /Y \"FM_Path1\" \"FM_Path2\"" ;
	~MoveMacScript =	"do shell script \"mv \" & quoted form of \"FM_Path1\" & \" \" & quoted form of \"FM_Path2\"";

	~CopyPCScript =	"cmd /c COPY /Y \"FM_Path1\" \"FM_Path2\"" ;
	~CopyMacScript =	"do shell script \"cp \" & quoted form of \"FM_Path1\" & \" \" & quoted form of \"FM_Path2\"";

	$Script = Substitute(
			Case (
			~OS=	"Mac" and ~Command = "M" ; ~MoveMacScript ;
			~OS=	"Mac" and ~Command = "C" ; ~CopyMacScript ;
			~OS=	"PC" and ~Command = "M" ; ~MovePCScript ;
			~OS=	"PC" and ~Command = "C" ; ~CopyPCScript ;
			"ERROR" ) ;
				[ "FM_Path1" ; ~Path1 ] ; [ "FM_Path2" ; ~Path2 ] 
					) 


		];

$Script

)

In my work I move lots of files around for printing and sometimes need to switch between platforms. I was sick of using my separate custom functions for doing this and having to re-program.
Now I can use 1 custom function. I can make a variable and pass it to BOTH an Applescript AND a Send Event step and, regardless of the platform, I will have a correctly formatted terminal command to run in the script step that works on that platform.

The only bit that is not obvious is the "~MacServerPath ; ~PCServerPath ;".
You will have "different" beginnings to a Mac and Windows address for the same file. For example;
Mac: "/Volumes/DataServer/MainFolder/Subfolder/File.pdf"
Win: "X:/MainFolder/Subfolder/File.pdf"

Therefore I use the substitute command where I would (in this case) replace "/Volumes/DataServer/" with "x:/" were I going onto a PC but the path was formed on the Mac (and the opposite).
90% of the time this step is unnecessary so I just put " 1 ; 1 ;" in there if the solution is a single platform job and it cancels itself out.

PS. This is my first upload, any constructive criticism would be appreciated

Comments

		Stuart Rechter May 30, 2022
Hi Reeve, this looks really good. Is there a way I can check for an existing file with the same name on the new path, before running this function, so that I can sequentially number my file to make it unique before the move?

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CopyMoveFile ( ~OriginalFilePath ; ~EndFilePath ; ~MacServerPath ; ~PCServerPath ; ~MoveOrCopy )

Comments

Support this website.

Support this website.