FrontTabPanelNames ( param )

Get the objectnames of all the frontmost panels on a layout or from the given list on the current layout

Average rating: 4.5 (4 votes) Log in to vote

Menno van Beek - Show more from this author
Van Beek Zakelijke Software
https://www.vbzs.nl

Sample input:

FrontTabPanelNames ( "" )

Sample output:

Entry
Planning

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
##########################################################################
##
## GetFrontTabPanels - Custom Function
## Author:
## Menno van Beek - Van Beek Zakelijke Software - Woerden, the Netherlands
## Format:
## GetFrontTabPanels ( objectlist )
## Recursion: True
## Parameters:
## Text - Either empty or list of objectnames from current layout
## 	
## This functions assumes that tabpanels that contain other (named) 
## tabpanel(s) all have an object name. Only the visible tabpanels
## Will be listed.
## 	
## Data type returned:
## text
## Description:
## Returns the objectnames for which the 
## layoutobjectattribute: "isFrontTabPanel" = true
## June 13, 2017
##########################################################################
*/

Let ( [ 
	dobj = "dummyobject" ; 
	plist = If ( param ≠ "" ; 
		  List ( if ( GetValue ( param ; 1 ) ≠ dobj ; dobj ) ; param ) ; 
		    List ( dobj ; 
		      Substitute ( 
			LayoutObjectNames ( 
			  Get ( FileName ) ; Get ( LayoutName ) ) ; 
				[ "<¶" ; "" ] ; 
				[ ">¶" ; "" ] ; 
				[ "¶<" ; "" ] ; 
				[ "¶¶" ; ¶ ] ) ) ) ; 
	object = GetValue ( plist ; 2 ) ; 
	enclby = GetLayoutObjectAttribute ( object ; "enclosingObject" ) ; 
	valid = If ( enclby = "" ; 1 ; 
		   GetLayoutObjectAttribute ( enclby ; "isFrontTabPanel" ) ) ; 
	atfront = If ( valid ; 
		   GetLayoutObjectAttribute ( object ; "isFrontTabPanel" ) ) ; 
	param = List ( dobj ; MiddleValues ( plist ; 3 ; 9999 ) )
] ; 
	Case ( 
		object = "" ; "" ; 
		List ( 
		   If ( atfront = 1 ; object ) ; 
			FrontTabPanelNames ( param ) ) )
)

This function returns a list of objectnames on a layout for which the function:
GetLayoutObjectAttribute ( object ; "isFrontTabPanel" ) = True

This function assumes that tabpanels that contain other (named) tabpanel(s) all have an object name. Only the visible tabpanels will be listed.

You can call the function with an empty parameter and it will determine the list of objects by itself. You can also provide a list yourself, if you have a very large amount of named objects.

The function uses head-recursion, so you can have no more than 9999 objects in the initial list

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

FrontTabPanelNames ( param )

Comments

Support this website.

Support this website.