WrapText ( text ; width )

Wraps a text string to a maximum line width (number of characters)

Average rating: 4.1 (14 votes) Log in to vote

Andy Smith - Show more from this author

Sample input:

WrapText (

Sample output:

Some moderately long sentence that needs to be wrapped to a shorter line width

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================================
 * WrapText ( text ; width )
 * 
 * PARAMETERS:
 *      text (string) - Text to wrap
 *      width (int) - Maximum line width (number of characters)
 *
 * RETURNS:
 *      (text) Wrapped such that every line is at most *width* characters long
 *
 * DEPENDENCIES:
 *      none
 *
 * NOTES:
 *      Tail recursive (max. 50,000 cycles?)
 *      Uses the private variable $~thisWrapTextOutput
 *      Will break words longer than width (line width is strict)
 *      Breaks on spaces only (not hyphens)
 *
 * RELEASE:
 *      2016-09-21 - Andy Smith andysmith.d@gmail.com
 * =====================================================
 * 
 */


If ( Length ( text ) ≤ width ;

  // Remaining text within char limit: return
  Let ([
    ~finalOutput = $~thisWrapTextOutput & text ;
    $~thisWrapTextOutput = ""
  ] ;
    ~finalOutput
  ) ;

  Let ( ~nextCR = Position ( text ; "¶" ; 1 ; 1 ) ;

  If ( ~nextCR > 0 and ~nextCR ≤ width ;

      // Next line within limit; add to output
      Let (
        $~thisWrapTextOutput = $~thisWrapTextOutput & Left ( text ; ~nextCR ) ;
        WrapText ( Right ( text ; Length ( text ) - ~nextCR ) ; width )
      ) ;
    
      // Break line at last space character, where possible
      Let ([
        ~truncated = Left ( text ; width - 1 ) ;
        ~lastSpace = Position ( ~truncated ; " " ; Length ( ~truncated ) ; -1 ) ;
        ~line = If ( ~lastSpace ; Left ( ~truncated ; ~lastSpace ) ; ~truncated ) ;
        $~thisWrapTextOutput = $~thisWrapTextOutput & ~line & "¶" ;
        ~text = Right ( text ; Length ( text ) - Length ( ~line ) )
      ];
        WrapText ( ~text ; width )
      )
    )
  )
)

I needed to wrap the output of a templated html email to a maximum line length, so I came up with this.

In short it wraps any lines longer than a certain width, breaking at space characters. Be aware that words longer than the specified width will break across lines.

I intend to add some test shortly. Please let me know if you come across any issues.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

WrapText ( text ; width )

Comments

Support this website.

Support this website.