ValidateUKPostcode

UK Postcode Validation

Average rating: 4.4 (26 votes) Log in to vote

ThomasSeidler - Show more from this author
The Good Book Company Ltd
http://www.thegoodbook.co.uk

Sample input:

ValidateUKPostcode( "WC1A 1AA")
ValidateUKPostcode( "XX1 Y8A")

Sample output:

1
0

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*

https://en.wikipedia.org/wiki/Postcodes_in_the_United_Kingdom#Validation

A9 9AA
A99 9AA
AA9 9AA
AA99 9AA

Exceptions:
A9A 9AA
AA9A 9AA
BFPO 9999

*/

Let ( [
_postcode = FilterC( Upper(_postcode) ; "AZ09" ) ;

_firstNumbers = Filter ( Left ( _postcode ; Length(_postcode)-3) ; "0123456789" ) ;

_postcodePrefixes = "¶AB¶AL¶B¶BA¶BB¶BD¶BF¶BH¶BL¶BN¶BR¶BS¶BT¶BX¶CA¶CB¶CF¶CH¶CM¶CO¶CR¶CT¶CV¶CW¶DA¶DD¶DE¶DG¶DH¶DL¶DN¶DT¶DY¶E¶EC¶EH¶EN¶EX¶FK¶FY¶G¶GIR¶GL¶GU¶GY¶HA¶HD¶HG¶HP¶HR¶HS¶HU¶HX¶IG¶IM¶IP¶IV¶JE¶KA¶KT¶KW¶KY¶L¶LA¶LD¶LE¶LL¶LN¶LS¶LU¶M¶ME¶MK¶ML¶N¶NE¶NG¶NN¶NP¶NR¶NW¶OL¶OX¶PA¶PE¶PH¶PL¶PO¶PR¶RG¶RH¶RM¶S¶SA¶SE¶SG¶SK¶SL¶SM¶SN¶SO¶SP¶SR¶SS¶ST¶SW¶SY¶TA¶TD¶TF¶TN¶TQ¶TR¶TS¶TW¶UB¶W¶WA¶WC¶WD¶WF¶WN¶WR¶WS¶WV¶YO¶ZE¶" ;
_matchedPrefix = FilterValues ( ¶ & Left(_postcode;Position(_postcode;_firstNumbers;0;1)-1) & ¶ ; _postcodePrefixes ) ;

_lastNumber = Filter( Middle(_postcode;Length(_postcode)-2;1) ; "0123456789" ) ;
_last2Chars = Filter( Right(_postcode;2) ; "ABDEFGHJLNPQRSTUWXYZ" ) ;


_valid = Case (
	Left(_postcode;4) = "BFPO"; 
	Let ( _rhs = Right(_postcode ; Length(_postcode)-4 ) ; _rhs and Length(_rhs)<=4 and ( Filter ( _rhs ; "0123456789") = _rhs ) );
	
	// fail if not matched prefix or missing compulsory elements: compliant last two characters; first digit(s) and last digit
	not ( Length(_matchedPrefix) and Length(_lastNumber) and (Length(_last2Chars)=2) and Length(_firstNumbers) ) ; 0 ;

	/* AA9A 9AA */
	_matchedPrefix = "WC" or 
		(_matchedPrefix = "EC" and NumInRange ( _firstNumbers ; 1 ; 4 )) or 
		Left(_postcode;4)= "SE1P" or 
		(_matchedPrefix="SW" and _firstNumbers = 1) ; 
	Length(_postcode)=7 and Length( Filter( Middle(_postcode;4;1) ; "ABEHMNPRVWXY" ) ) ;
	
	/* A9A 9AA */
	Length( FilterValues( Left(_postcode;3); "E1W¶N1C¶N1P" ) ) ; Length(_postcode)=6 and Length( Filter( Middle(_postcode;3;1) ; "ABCEFGHJKPSTUW" ) ) ;
	
	/* A9 9AA¶A99 9AA */
	Length( FilterValues ( _matchedPrefix ; "B¶E¶G¶L¶M¶N¶S¶W" ) ) ; Length(_postcode)=5 or Length(_postcode)=6 ;
	
	/* AA9 9AA¶AA99 9AA */ Length(_postcode)=6 or Length(_postcode)=7
)
] ;

_valid

)

Validates UK postcode by crude rule base provided in Wikipedia

[updated to make sure it worked!! :)]

Comments

		Tom Hames, B&P Fabrications Apr 18, 2019
Hi there, I have Copied your link and pasted into functions, with the Parameter "FilterC", however when I click ok it says it is expecting A number, A Text Constant etc and is highlighting the first bracket. Any Clues? Let ( [ _postcode = FilterC ( Upper(_postcode) ; "AZ09" ) ;

		Tom Hames, B&P Fabrications Apr 18, 2019
The first bracket after "FilterC"

		Tom Hames, B&P Fabrications Apr 18, 2019
The first bracket after "FilterC"

		Ben, realseeds Feb 13, 2024
BEWARE! Before you waste any time on it, I'm not sure what is up with this function, but as of 2024 it is not valid filemaker code. There is an error in the first line there should not be a C after the word filter. But even so, for me the filter command does not work as specifying AZ09 but needs abcdefghijklmnopqrstuvwxyz0123456789 specified And the command NumInRange does not appear to be valid filemaker syntax either.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValidateUKPostcode

Comments

Support this website.

Support this website.