CF_GetFieldAttributes ( Fieldname ; ShowFieldAttributes )

When you hover above a [Field] this Custom Function in combination with [Tooltip] will give you access to all available information about each and every [Field] on the layout

Average rating: 4.5 (23 votes) Log in to vote

Hans Nagelgast - Show more from this author
None
http://HTTP://none

Sample input:

CF_GetFieldAttributes ( Self ; 1 )

Sample output:

Comments
• Comments about this field

Table Occurrence:
• [TABLE_01]

Field Name:
• [Field_01]

Field Attributes:
• Storage [UnstoredCalc]
• Field Type [Text]
• Index [Unindexed]
• Repetition [1] of [1]

Field Content:
• [Field Content]
• [13] Bytes

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [
$GetFieldName 		= GetFieldName ( Fieldname ) ;
$GetTableAttributes 	= "• [" & Substitute ( $GetFieldName ; [ "::" ; "]¶¶Field Name:¶• [" ]) ;
$GetFieldContent  	= If ( IsEmpty ( Fieldname ) ; "[-] [Empty" ; "["  & Fieldname ) & "]" ;				// Get Field Content
$GetFieldComment	= FieldComment ( Get ( FileName ) ; GetFieldName ( Fieldname )) ;				// Get Field Comment
$GetTooltipParm 	= Middle ( $GetFieldComment ; Position ( $GetFieldComment ; "{" ; 1 ; 1) +1 ; (Position ( $GetFieldComment ; "}" ; 1 ; 1) -1) - Position ( $GetFieldComment ; "{"  ; 1 ; 1)) ;	 // {T0000}
$GetTooltipParmText 	= If ( IsEmpty ( $GetTooltipParm ) ; "T1111" ; $GetTooltipParm );				// {T0000}
$GetActiveRepetition 	= If( Get ( ActiveRepetitionNumber ) = 0 ; "[-]" ; "[" & Get ( ActiveRepetitionNumber ) & "]" ) ;
$T1 			= If ( IsEmpty ( $GetFieldComment ) ; "1" ; Middle ( $GetTooltipParmText ; 2 ; 1 ) ) ;		// {T1000} Comments Only
$T2 			= If ( IsEmpty ( $GetFieldComment ) ; "1" ; Middle ( $GetTooltipParmText ; 3 ; 1 ) ) ;		// {T0100} Table Occurrence & Field Name Only
$T3 			= If ( IsEmpty ( $GetFieldComment ) ; "1" ; Middle ( $GetTooltipParmText ; 4 ; 1 ) ) ;		// {T0010} Field Attributes Only
$T4 			= If ( IsEmpty ( $GetFieldComment ) ; "1" ; Middle ( $GetTooltipParmText ; 5 ; 1 ) ) ;		// {T0001} Field Content Only
$GetFieldType 		= Let ( [ TOFieldJoin = GetFieldName ( FieldName ) ] ; Evaluate ( "FieldType ( " & " " & "Get ( FileName) " & " ; " & "\"" & TOFieldJoin & "\"" &  " )" ));

$GetFieldAttributes		= 
"Field Attributes:"
& "¶• Storage [" 		& GetValue ( Substitute ( $GetFieldType ; [" ";"¶"] ) ; 1 ) & "]"
& "¶• Field type [" 	& GetValue ( Substitute ( $GetFieldType ; [" ";"¶"] ) ; 2 ) & "]"
& "¶• Index [" 		& GetValue ( Substitute ( $GetFieldType ; [" ";"¶"] ) ; 3 ) & "]"
& "¶• Repetition [" 	& Get ( ActiveRepetitionNumber ) & "] of [" & GetValue ( Substitute ( $GetFieldType ; [" ";"¶"] ) ; 4 ) & "]"

/* What it is? 
Field names must be in the format tablename::fieldname to specify a field that exists in a table different from the current table. The result has four values separated by ¶
• The first value is either [Standard], [StoredCalc], [Summary], [UnstoredCalc], [External(Secure)], [External(Open)], or [Global].
• The second value is the field type: [Text], [Number], [Date], [Time], [Timestamp], or [Container].
• The third value is [Indexed] or [Unindexed].
• The fourth value is the [Maximum number of Repetitions] defined for the field (if the field isn’t defined as a repeating field, this value is 1). 
*/
] ;
Case(
not IsEmpty ( ShowFieldAttributes ) ;
If ( $T1=1 ; If ( IsEmpty ( $GetFieldComment ) ; "" ; "Comments:¶• " & $GetFieldComment ) ; "")
& If ( $T1=1 and $T2=1 and not IsEmpty ( $GetFieldComment ) ; "¶¶" ; "" )	& If ( $T2=1 ; "Table Occurrence:¶" & Substitute ( $GetTableAttributes & "]" ; "]]" ; "]" ) ; "")

& If ( $T2=1 and $T3=1 ; "¶¶" ; "" ) 	& If ( $T3=1 ; $GetFieldAttributes ; "" )
& If ( $T3=1 and $T4=1; "¶¶" ; "" ) 	& If ( $T4=1 ; "Field Content:¶• " &$GetFieldContent
& "¶• "  & If ( IsEmpty ( Fieldname ) ; "[-] Bytes" ; "[" & Length ( Fieldname ) & "] Bytes" ) ;"" ) ; 

"Comments:¶• " & $GetFieldComment &" " & $GetActiveRepetition
) // END CASE

/*
What it is? 
• Using this Custom Function in combination with the [Tooltip] will give you access to all available information about a specific [Field].
• Just enter [CF_GetFieldAttributes ( Self ; 1 )] in the [Tooltip] calculation and you ready to go.
• If you define [ShowTootip] as a global field you can switch it on and off (for all fields) as you please.
• With the controls {T1111} in the Field comments you can control what is displayed.
• Hope this Custom Function comes in handy. Hans Nagelgast, Oss The Netherlands
• http://www.briandunning.com/cf/1779

How does it work? 
• Tooltip		= CF_GetFieldAttributes ( Self ; 1 )
• Fieldname	= [Self] 
• ShowTootip	= [Empty] = Off; [1] = On
• Result		= 	Comments:		* {T1000} Comments only
			• Comments about this field	

			Table Occurrence:	* {T0100} Table Occurrence & Field Name Only
			• [TABLE_01]

			Field Name:
			• [Field_01]

			Field Attributes:		* {T0010} Field Attributes Only
			• Storage [UnstoredCalc]
			• Field Type [Text]
			• Index [Unindexed]
			• Repetition [1] of [1] 	* Only correct when field is active

			Field Content:		* {T0001} Field Content Only
			• [Field Content]
			• [13] Bytes  

*/

) // END LET

What it is?
• Using this Custom Function in combination with the [Tooltip] will give you access to all available information about a specific [Field].
• Just enter [CF_GetFieldAttributes ( Self ; 1 )] in the [Tooltip] calculation and you are ready to go.
• If you define [ShowFieldAttributes] as a global field you can switch it on and off (for all fields) as you please.
• With the controls {T1111} in the Field comments you can control what is displayed.
• Hope this Custom Function comes in handy. Hans Nagelgast, Oss The Netherlands

p.s. I modified the CF name. Was CF_Tooltip ( Fieldname ; ShowTooltip )

Comments

		Vyke, Washington DC Jul 6, 2015
I absolutely, without a doubt, love this CF. Thank you!

		Steve M, Broomall, PA Aug 21, 2015
Unbelievable, the way your brain works......very cool

		Phil McGeehan, Poole, UK Dec 6, 2016
Very helpful. Thank you Hans!

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CF_GetFieldAttributes ( Fieldname ; ShowFieldAttributes )

Comments

Support this website.

Support this website.