DigitSequences ( text ; numberOfDigits )

Extracts digit sequences

Average rating: 4.6 (20 votes) Log in to vote

Daniele Raybaudi
ACI
http://www.aci.it

Sample input:

DigitSequences ( "ab023 23aaaa254" ; 3 )
DigitSequences ( "p.iva05816830581abc23" ; 11 )

Sample output:

023¶254
05816830581

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
DigitSequences ( text ; numberOfDigits ) Custom Function
recursive
Extracts all the digit sequences composed of numberOfDigits found in a string of text
*/
Let([
adj = Substitute ( text ; " " ; "§§§" ) ;
adj = TrimAll ( Substitute ( TrimAll ( KanjiNumeral ( adj ) ; 1 ; 1 )
; [ "一" ; 1 ]
; [ "二" ; 2 ]
; [ "三" ; 3 ]
; [ "四" ; 4 ]
; [ "五" ; 5 ]
; [ "六" ; 6 ]
; [ "七" ; 7 ]
; [ "八" ; 8 ]
; [ "九" ; 9 ]
; [ "〇" ; 0 ]
; [ "§§§" ; " " ]
) ; 1 ; 1 ) ;
// puts a space between digits and whichever other character
word = LeftWords ( adj ; 1 ) ;
sequence = If ( Filter ( word ; 1234567890 ) = word  and Length ( word ) = numberOfDigits ; word ) ;
rest = RightWords ( adj ; WordCount ( adj ) - 1 )
];
Case(
WordCount ( adj ) ;
List (  sequence ;  DigitSequences ( rest ; numberOfDigits ) )
)
)

Extracts all the digit sequences composed of numberOfDigits found in a string of text.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.