TabNamesFrontmost ( )

Gets a return-delimited list of the object names of the frontmost (nested) tabs. Does not include sub-tabs whose parent is not ALSO frontmost. No recursion.

Average rating: 4.6 (27 votes) Log in to vote

Dan Shockley - Show more from this author

Sample input:

TabNamesFrontmost ( )

Sample output:

Contact Info
Phone Numbers

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// TabNamesFrontmost (  )
// version 2025-08-13

/* 
	Gets a return-delimited list of the object names of the frontmost (nested) tabs. Does not include sub-tabs whose parent is not ALSO frontmost. No recursion. 

	Builds a non-recursive calculation that includes only frontmost tabs whose parent is ALSO frontmost. Inspired by Todd Geist's code which included all frontmost tabs (regardless of parent state). See Todd's code at https://www.geistinteractive.com/2011/04/04/get-front-tab-names-with-out-recursion/

	To see how this works, you can temporarily remove the Evaluate and just view the 'mainCode' result. 


HISTORY
	2025-08-13 ( danshockley ): Updated documentation. Reformatted code. 
	2014-06-19 ( danshockley ): Created. 

*/

Let ( [
	  DQ = Char ( 34 )
	; CR = Char ( 13 )
	; TAB = Char ( 9 )
	/* setup the prefix and suffix vars for parts of the calc */
	; calcMainPrefix = "Let ([ " & CR & "frontTabs = " & DQ & DQ & CR & CR
	; calcMainSuffix = CR & "];" & CR & "frontTabs" & CR & ")"
	; calcObjPrefix = "; objName = \""
	; calcObjSuffix = 
		DQ & CR 
		& "; parentObjName = GetLayoutObjectAttribute ( objName ; \"enclosingObject\" )"
		& CR & "; parentIsFront = IsEmpty ( parentObjName ) or GetLayoutObjectAttribute ( parentObjName ; \"isFrontTabPanel\" )"
		& CR & "; frontTabs = List ( frontTabs ; If ( parentIsFront and GetLayoutObjectAttribute ( objName ; \"isFrontTabPanel\" ) ; objName ; " & DQ & DQ & " ) )"
	
	/* Get the object names from this layout */
	; objectNames = 
		Substitute (
			LayoutObjectNames ( Get ( FileName ); Get ( LayoutName ) )
			; [ "<" & CR ; "" ]
			; [ ">" & CR ; "" ]
			; [ ">" ; "" ]
			)

	/* build the overall code */
	; objectCode = calcObjPrefix & Substitute ( objectNames ; CR ; calcObjSuffix & CR & calcObjPrefix ) & calcObjSuffix
	
	; mainCode = calcMainPrefix & objectCode & calcMainSuffix
];
	Evaluate ( mainCode )
)

Gets a return-delimited list of the object names of the frontmost (nested) tabs. Does not include sub-tabs whose parent is not ALSO frontmost. No recursion. Inspired by Todd Geist's similar function, but this only returns tabs whose parent is ALSO frontmost. Avoids recursion by building a calculation string that is then evaluated. To see how it works, remove the Evaluate near the end and look at the 'mainCode' variable.

Comments

		Phil, Gold Coast, Qld Jun 19, 2014
Is this for sticky tabs? i.e. return to a layout to find the tabs in the same place you left them (Without going to a new window then closing it).

		Dan Shockley Jun 19, 2014
Absolutely. You can have a script that loops over the values stored from this, going to each in turn.

		Bruce Robertson Jun 21, 2014
Nicely done. Simple, non-recursive.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TabNamesFrontmost ( )

Comments

Support this website.

Support this website.