ConvertToBase ( number ; base ; charSet )

Convert a decimal number to any other base

Average rating: 4.5 (25 votes) Log in to vote

Steven R. Allen
Richard Carlton Consulting, Inc.
http://www.rcconsulting.com

Sample input:

Ex. 1: ConvertToBase ( 420 ; 7 ; "0123456" )

Ex. 2: ConvertToBase ( 420 ; 40 ; "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcd" )

Ex. 3: ConvertToBase ( 777 ; 14 ; "!@#$%^&*()1234" )

Sample output:

Ex. 1: 1140

Ex. 2: AK

Ex. 3: $4*

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
 * Created: 2014-01-16
 * By: Steven R. Allen, Richard Carlton Consulting, Inc.
 * Version: 1.0
 * 
 * Purpose: Conversion of representation of a number from decimal with Arabic numerals to any base and any character set.
 * 
 * Notes:
 *       - FileMaker does not have a function to get the Logarithm of a number in an arbitrary Base.  It only has Log(), which is Base 10; Lg(), which is base 2; and Ln(), which is base e (the natural logarithm).  However, a quick bit of Googling revealed that one can achieve an arbitrary Log Base using the Logs in base 10, like so: Log ( number ) / Log ( base )
 *
 *      - There is one restriction that I can think of: each value that could go in any particular place has to be represented by a single character; what character is used for what value is completely arbitrary, however.
 *
 *      - Also, there is an assumption that the character set is coded to values starting at zero on the left, and rising by +1 as it proceeds to the right, like we are used to reading the arabic numeral sequence 0123456789, etc.   You can really confuse the heck out of people if you mix this up, putting, for example, "9876543210". :)
 *	
 *      -Finally, the zero padding part is because this algorithm jumps through the places that actually will have values assigned in the new base, skipping those that won't.  So I added a pad of the number of places skipped, filling it with the requisite number of the zero character from the new base's character set.  The cool thing (to me, anyway) is that I did it without having to recurse, like so many of the Pad functions I've seen out there do.
 */

Case ( number < base ; Middle ( charSet ; number + 1 ; 1 ) ; 

Let ([
	power = Floor ( Log ( number ) / Log ( base ) )
;	place = base ^ power
;	value = Div ( number ; place )
;	next = number - (place * value)
;	nextPower = Case ( next ; Floor ( Log ( next ) / Log ( base ) ) ; 0 )
;	digit = Middle ( charSet ; value + 1  ; 1 )

;	padZeroesNeeded = power - nextPower -  GetAsBoolean ( next )
;	padZeroes = Substitute ( Right ( Right ( 10 ^ power ; Length ( 10 ^ power ) - 1 ) ; padZeroesNeeded ) ; "0" ; Middle ( charSet ; 0 ; 1 ) )
;	output = digit & padZeroes
];

output & Case ( next ; ConvertToBase ( next ; base ; charSet ) )

) )

This function takes any decimal number and converts it to any base representation, using any arbitrary characters to represent the new base's values set.

This can be used in rather conventional ways (see Ex. 1 & 2), or in completely arbitrary ways that have no basis in any regularly used character set (see Ex. 3), and in fact might even break conventional character set expectations (see, again, Ex. 3, wherein the character "4" actually represents the [decimal] value 13).

Comments

		comment, VR Jan 20, 2014
I believe this can be simpler if done from right to left: http://www.briandunning.com/cf/218

		Shawn A. Krueger, MN Aug 2, 2016
Took a look at this, and the one mentioned in the other comment. The other one is easier to grok, but it requires that the character set be "hard coded" inside the CF. This one lets you pass the character set as a param, and therefore is a little more flexible. It also does its work without recursion, whereas the other one does use recursion. Probably not a performance issue, unless you get into really high number sets. Haven't tested for performance. I can see pros/cons to either way. If you need different alpha character sets in the same file, this one will be more flexible. If you only need/want 1, and you want 1 place to change/update it, the other one may be simpler.

		nonio, lopuu Apr 4, 2020
Thanks for the function. ConvertToBase ( 999999999999999999; 7; "0123456" ) = 1535844346544330041530 The internet says 1535044306544330041530 Thanks

		nonio, lopuu Apr 4, 2020
Thanks for the function. ConvertToBase ( 999999999999999999; 7; "0123456" ) = 1535844346544330041530 The internet says 1535044306544330041530 Thanks

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ConvertToBase ( number ; base ; charSet )

Comments

Support this website.

Support this website.