GeoBoxBounds ( latitude ; longitude ; radiusInMeters )

Calculates coordinates for search bounding box around a location

Average rating: 4.6 (28 votes) Log in to vote

Jeremy Bante
Beezwax
http://beezwax.net/

Sample input:

/* Coordinates for geobox bounding neighborhood up to 1 km away from FileMaker, Inc., headquarters */

LocationBoxBounds ( 37.4064806 ; -121.984204 ; 1000 )

Sample output:

37.3974922470474878
37.4154689529525122
-121.9955194140472811
-121.9728885859527189

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*******************************************************************************
 * LocationSquareBounds ( latitude ; longitude ; radiusInMeters )
 * Calculates the approximate coordinate bounds for an approximately square
 * region around a point on the surface of the Earth. This can be useful for
 * finding data within a certain distance of a reference point.
 *
 * The results are calculated by a version of the Haversine formula worked in 
 * reverse, based on a spherical approximation of the surface of the Earth.
 *
 * Use FileMaker's GetValue function to retrieve each value of the return-delimited result.
 *
 * When the location box includes a pole, the function will return the
 * appropriate values to perform a find for coordinates enclosed by the latitude
 * closer to the equator. For example: [90, 88, -180, 180] for a region around
 * the north pole.
 *
 * When the geobox crosses the antimeridian (180º/-180º longitude), the function
 * will return a west boundary coordinate greater than the east boundary
 * coordinate. In this situation, a coordinate search within the geobox should
 * be broken into separate searches: one search from the west bound to 180º, and
 * another from -180º to the east bound.
 *
 * The bounding region's approximation to a square shape is less accurate as
 * radiusInMeters grows large and as the region approaches either pole. However,
 * the region will always contain the circular region of the same radius. Square
 * bounding regions are more computationally convenient for finding data.
 * Developers needing an exact circular region can use a square region to
 * constrain the available data to a smaller found set, then use the GeoDistance
 * function to omit points between the circular and square neighborhoods of the
 * reference point.
 *
 * @parameter latitude: Degrees between -90 and 90 for center of geobox
 * @parameter longitude: Degrees between -180 and 180 for center of geobox
 * @parameter radiusInMeters: The distance in meters from the center of the
 * region to the closest points on the edges of the square bounding region.
 *
 * @return A return-delimited list of numbers:
 * 1. The south latitude boundary for the calculated region
 * 2. The north latitude boundary for the calculated region
 * 3. The west longitude boundary for the calculated region
 * 4. The east longitude boundary for the calculated region
 *
 * @history 2012-09-26 - Jeremy Bante <http://scr.im/jbante> - Created
 * @history 2012-09-27 - Jeremy Bante <http://scr.im/jbante> - accommodating
 * regions that may span a pole or the antimeridian.
 * @history 2014-07-30 - Jeremy Bante <http://scr.im/jbante> - correcting
 * calculation of longitudes at high latitudes.
 *
 * @see http://en.wikipedia.org/wiki/Haversine_formula
 ******************************************************************************/

Let ( [
	_earthRadius = 6374447 ;	// average in meters

	// calculate latitude bounds
	_angularDistance = radiusInMeters / _earthRadius ;
	_latitudeOffset = Degrees ( _angularDistance ) ;
	_north = latitude + _latitudeOffset ;
	_south = latitude - _latitudeOffset ;
	_wrapNorth = _north > 90 ;
	_wrapSouth = _south < -90 ;
	_northBound =
		Case (
			_wrapNorth ; 90 ;
			_wrapSouth ; Max ( _north ; -180 - _south ) ;
			_north
		) ;
	_southBound =
		Case (
			_wrapSouth ; -90 ;
			_wrapNorth ; Min ( _south ; 180 - _north ) ;
			_south
		) ;

	// calculate longitude bounds
	_longitudeOffset =
		Degrees ( Acos (
			1
			- ( 1 - Cos ( _angularDistance ) )
			/ Cos ( Radians ( latitude ) ) ^ 2
		) ) ;
	_eastBound =
		If ( _wrapNorth or _wrapSouth ;
			180 ;
			/* Else */ longitude + _longitudeOffset
		) ;
	_eastBound =
		If ( _eastBound > 180 ; _eastBound - 360 ; /* Else */ _eastBound ) ;
	_westBound =
		If ( _wrapNorth or _wrapSouth ;
			-180 ;
			/* Else */ longitude - _longitudeOffset
		) ;
	_westBound =
		If ( _westBound < -180 ; _westBound + 360 ; /* Else */ _westBound )
] ;
	List (
		_southBound ;
		_northBound ;
		_westBound ;
		_eastBound
	)
)

Calculates the approximate coordinate bounds for an approximately square region around a point on the surface of the Earth. This can be useful for finding data within a certain distance of a reference point. For example:

Set Variable [$geoBox; Value:LocationBoxBounds ( $latitude ; $longitude ; $radius)]
Enter Find Mode []
Set Field [Table::latitude; Value:GetValue ( $geoBox ; 1 ) & "..." & GetValue ( $geoBox ; 2 )]
Set Field [Table::longitude; Value:GetValue ( $geoBox ; 3 ) & "..." & GetValue ( $geoBox ; 4 )]
Perform Find []

This function is similar to the GeoBox function by Steve Murray, but it provides more helpful results for search regions that may include a pole or cross the antimeridian (180°/-180° longitude). The above script example naïvely assumes that the search region will not cross the antimeridian; a more complete application will include slightly more complicated logic.

The results of this function define an approximately square region. If your application requires search within a circular region, you can perform a find like above to start with a manageable number of records, then compare each record to the center of your search region with the GeoDistance function to omit points between the circular and square neighborhoods of the center point.

Comments

		Carsten Warnich, Brabrand, Denmark Jul 29, 2014
I've found that there is an error in this function when it comes to calculating the longitude values. I changed the script to this - and now it works: // calculate longitude bounds ~longitudeOffset = (radiusInMeters/1000)*((1/Cos(Radians ( latitude ))) /111,32); 111,32 is the approximate distance represented by 1 degree longitude at the Equator.

		Jeremy, USA Jul 30, 2014
Thanks for catching that! I opted for a different solution by working the haversine formula backwards, which appears to work fine now.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GeoBoxBounds ( latitude ; longitude ; radiusInMeters )

Comments

Support this website.

Support this website.