LowDiscrepancySequence ( index )

Generates low-discrepancy (even distances between values) sequences

Average rating: 4.6 (25 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

List (
LowDiscrepancySequence ( 1 );
LowDiscrepancySequence ( 2 );
LowDiscrepancySequence ( 3 );
LowDiscrepancySequence ( 4 );
LowDiscrepancySequence ( 5 );
LowDiscrepancySequence ( 6 );
LowDiscrepancySequence ( 7 );
LowDiscrepancySequence ( 8 );
LowDiscrepancySequence ( 9 );
LowDiscrepancySequence ( 10 )
)

Sample output:

.5
.25
.75
.125
.625
.375
.875
.0625
.5625
.3125

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * LowDiscrepancySequence ( index )
 *
 * PURPOSE:
 *		When called with successive values for index, this function generates a
 *		low discrepancy sequence designed to maximize the distance between
 *		successive 1-dimensional elements in the sequence.
 *
 * RETURNS:
 *		A number, 0 ≤ result < 1
 *
 * PARAMETERS:
 *		index: A non-negative integer
 *
 * DEPENDENCIES: none
 *
 * HISTORY:
 *		CREATED on 2012-03-12 by Jeremy Bante <http://scr.im/jbante>.
 *		MODIFIED on 2012-03-23 by Jeremy Bante <http://scr.im/jbante> to
 *		correctly handle index = 0.
 *
 * REFERENCES:
 *		http://en.wikipedia.org/wiki/Low-discrepancy_sequence
 * =====================================
 */

Case (
	/* Step 0, set-up */
	not $~seq.step;
		Let ( [
			~index = Int ( index );
			$~seq.step = If ( ~index ≥ 0 ; 1 ; /* Else, error */ -1 )
		];
			LowDiscrepancySequence ( ~index )
		);

	/* Step 1, reverse binary representation of index */
	$~seq.step = 1;
		Let ( [
			$~seq.i = $~seq.i + 1;
			~binaryDigit = Mod ( index ; 2 );
			~remainder = Div ( index ; 2 );
			$~seq.result = $~seq.result + ~binaryDigit * 2 ^ -$~seq.i;

			$~seq.step = If ( ~remainder ; $~seq.step ; /* Else */ $~seq.step + 1 )
		];
			LowDiscrepancySequence ( ~remainder )
		);

	/* Step 2, clean-up and return result */
	$~seq.step = 2 or $~seq.step = -1;
		Let ( [
			~error = $~seq.step = -1;
			~result = $~seq.result;

			// purge variables
			$~seq.i = "";
			$~seq.result = "";
			$~seq.step = ""
		];
			If ( ~error ; "?" ; /* Else */ ~result )
		)
)

When called with successive values for index, this function generates a low discrepancy sequence designed to maximize the distance between successive 1-dimensional elements in the sequence.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

LowDiscrepancySequence ( index )

Comments

Support this website.

Support this website.