BuildRSSFeed ( rssTitle ; rssPubDate ; IDLink ; rssLink ; rssDescription ; rssXMLurl ; rssEnclosure )

The easiest way to build RSS Feeds

Average rating: 4.4 (34 votes) Log in to vote

Roger Biel
2Geckos Consulting, LLC
www.2geckos.com

Sample input:

BuildRSSFeed( rssTitle ; rssPubDate ; IDLink ; rssLink ; rssDescription ; rssXMLurl ; rssEnclosure )

Sample output:

returns RSS Feed ready for publishing

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* BuildRSSFeed( rssTitle ; rssPubDate ; IDLink ; rssLink ; rssDescription ; rssXMLurl ; rssEnclosure )
Custom function Dependencies: Text2HTM ; rssDateCode ; MimeType ; Julian
Variables: rssTitle ; rssPubDate ; IDLink ; rssLink ; rssDescription ; RSSURL ; rssEnclosure ; rssCategory 
-------------------------sample data-------------------------------
*/
Let( [FirstRun = IsEmpty( $RSSHeader ) ; 
LastRun = IsEmpty( rssTitle & rssPubDate & IDLink & rssLink & rssDescription & rssXMLurl & rssEnclosure ) ; 

//------------Confiure default values--------------------------------------------
rssAuthor = "info@2geckos.com( 2Geckos Consulting, LLC )" ; 
rssEditor = rssAuthor ; 
rssLastPubDate = rssPubDate ; 
rssCopyright = "http://www.webwizdirect.com/ww2g/copyright.html" ; 
rssWebmaster = "info@2geckos.com( 2Geckos Consulting, LLC )" ; 
rssContact = "Roger Biel" ; 
rssTimeTillLive = 1440 ; 
rssCategory = "Website Maintenance" ; 
Podcast = 0 ; 
rssLink = If( IsEmpty( rssLink ) ; "http://www." & $$Domain ; rssLink ) ; 

//--------------Format initalize, and verify data---------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------------------------------------------
rssEnclosureLink = If( IsEmpty( rssEnclosure ) ; "http://www.webwizdirect.com/images/2Geckos_logo.26.png" ; ValidURL( "URL" ; rssEnclosure ) ) ; 
rssGenerator = "WebWizDirect( www.webwizdirect.com )" ; 
//---------------------------------------------------------------------------------------------------------------------------------------
IDLink = If( IsEmpty( IDLink ) ; "IDran" & Julian( rssPubDate ) ; IDLink ) ; 
rssPermaLink = If( IsEmpty( ValidURL( "Domain" ; IDLink ) ) ; "false" ; "true" ) ; 
rssEditor = If( PatternCount( rssEditor ; "@" )<1 ; rssWebmaster ; rssEditor ) ; 
$$RSSerrors = If( FirstRun ; "" ; $$RSSerrors ) ; //reset errors log
rssEditor = Substitute( rssEditor ; ["<" ; "( "] ; [">" ; " )"] ) ; 
rssEnclosureLength = 1000 ; 
rssEnclosureType = MimeType( rssEnclosureLink ; "text" ) ; 
rssEnclosure = If( IsEmpty( rssEnclosureLink ) ; "" ; Substitute( BuildRSSFeedLib( "enclosure" ) ; 
	["rssEnclosureLength" ; rssEnclosureLength] ; ["rssEnclosureType" ; rssEnclosureType] ; ["rssEnclosureLink" ; rssEnclosureLink] ) ) ; 
rssPodcast = If( not Podcast ; "" ; BuildRSSFeedLib( "iTunes" ) ) ; 
rssDescription = XMLencode( Text2HTM( rssDescription ) ) ; 
rssCategory = XMLencode( rssCategory ) ; 
rssLink = XMLencode( ValidURL( "URL" ; rssLink ) ) ; 
rssTitle = XMLencode( rssTitle ) ; 
rssPubDate = rssDateCode( rssPubDate ; rssPubDate ) ; 
rssLastPubDate = rssDateCode( rssLastPubDate ; rssLastPubDate ) ; 
rssPodcastHeader = If( not Podcast ; "" ; BuildRSSFeedLib( "iTunesHeader" ) ) ; 

Header = Substitute( BuildRSSFeedLib( "Header" )& rssPodcastHeader ; //-------------Create RSS Feed header---------------------
	["rssAuthor" ; rssAuthor] ; ["rssCopyright" ; rssCopyright] ; ["rssDescription" ; rssDescription] ; ["rssEditor" ; rssEditor] ; 
	["rssGenerator" ; rssGenerator] ; ["rssLastPubDate" ; rssLastPubDate] ; ["rssEnclosureLink" ; rssEnclosureLink] ; 
	["rssLink" ; rssLink] ; ["rssXMLurl" ; rssXMLurl] ; ["rssPubDate" ; rssPubDate] ; ["rssTimeTillLive" ; rssTimeTillLive] ; ["rssTitle" ; rssTitle] ; 
	["rssWebmaster" ; rssWebmaster] ) ; 
$$RSSerrors = Case( LastRun ; $$RSSerrors ; not FirstRun ; $$RSSerrors ; 
	//-----------Validate that RSS article is properly formatted-------------
	PatternCount( Header ; "title>" )<2 ; "ERROR in Header Title of " & rssTitle & ¶ & Header ; 
	PatternCount( Header ; "description>" )<2 ; "ERROR in Header Description of " & rssTitle & ¶ & Header ; 
	PatternCount( Header ; "pubdate>" )<2 ; "ERROR in Header Pubdate of " & rssTitle & ¶ & Header ; 
	PatternCount( Header ; "webMaster>" )<2 ; "ERROR in Header WebMaster of " & rssTitle & ¶ & Header ; 
	IsEmpty( rssTitle ) ; "ERROR in Header Title is missing¶" & Header ; "" ) ; 

$RSSHeader = Case( not FirstRun ; $RSSHeader ; not IsEmpty( $$RSSerrors ) ; "" ; Header ) ; 

item = Substitute( BuildRSSFeedLib( "Body" ) ; //-------------Create RSS Feed article----------------------------
	["IDLink" ; IDLink] ; ["rssAuthor" ; rssAuthor] ; ["rssDescription" ; rssDescription] ; ["rssEnclosure" ; rssEnclosure] ; ["rssLink" ; rssLink] ; 
	["rssPermaLink" ; rssPermaLink] ; ["rssPodcast" ; rssPodcast] ; ["rssPubDate" ; rssPubDate] ; ["rssTitle" ; rssTitle] ) ; 
ItemError = Case( FirstRun or LastRun ; "" ; //-----------Validate that RSS article is properly formatted--------------------
	PatternCount( item ; "title>" )<2 ; "ERROR in item Title of " & rssTitle & ¶ & item ; 
	PatternCount( item ; "description>" )<2 ; "ERROR in item Description of " & rssTitle & ¶ & item ; 
	PatternCount( item ; "pubdate>" )<2 ; "ERROR in item PubDate of " & rssTitle & ¶ & item ; 
	PatternCount( item ; "author>" )<2 ; "ERROR in item Author of " & rssTitle & ¶ & item ; 
	IsEmpty( rssTitle ) ; "ERROR in item Title is missing¶" & item ; "" ) ; 

$RSSBody = $RSSBody & Case( FirstRun or LastRun ; "" ; not IsEmpty( ItemError ) ; "" ; item ) ; 
$$RSSerrors = $$RSSerrors & ItemError] ; 

Case( IsEmpty( $RSSHeader ) ; "" ; //"ERROR in RSS Header" ; 
	FirstRun ; $RSSHeader ; //"Header stored in $RSSHeader = " & rssTitle ; 
	not IsEmpty( rssTitle ) ; item ; //"Body stored in $RSSBody = " & rssTitle ; 
	$RSSHeader & $RSSBody & "</channel></rss>¶" )
)

There are many ways to publish RSS Feeds but this is the simple way.
Enter the information and a valid RSS feed will be generated.

The first time the function is exicuted it creates the RSS Header, then with a script loop add the information for each feed item, when complete execute the funtion with no parameters to add the footer to the RSS Feed.

I use CNS FTPiT to upload the feed to the web.
if the default values are refferenced then fewer command line options are needed.

I use this function in any application that needs to report results to others.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

BuildRSSFeed ( rssTitle ; rssPubDate ; IDLink ; rssLink ; rssDescription ; rssXMLurl ; rssEnclosure )

Comments

Support this website.

Support this website.