BusinessHolidays ( calendarYear )

Returns a list of observed holidays in calendarYear

Average rating: 4.4 (28 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

BusinessHolidays ( 2011 )

Sample output:

1/17/2011
2/21/2011
5/30/2011
7/4/2011
9/5/2011
10/10/2011
11/11/2011
11/24/2011
12/26/2011

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * BusinessHolidays ( calendarYear )
 *
 * RETURNS:
 *		A ¶-delimited list of the dates of observed holidays in calendarYear
 *
 * PARAMETERS:
 *		calendarYear
 *
 * DEPENDENCIES: none
 *
 * NOTES:
 *		This version of this function includes observed U.S. federal holidays.
 *		It should be modified to include any holidays observed by the users of
 *		each particular system.
 *
 * HISTORY:
 *		CREATED on 2011-10-18 by Jeremy Bante http://scr.im/jbante.
 * =====================================
 */

List (
	// New Years Day
	Let ( [
		~date = Date ( 1 ; 1 ; calendarYear );
		~day = DayOfWeek ( ~date )
	];
		Case (
			~day = 1 ; ~date + 1;	// following Monday
			~day = 7 ; "";	// previous Friday (in previous year)
			/* Else */ ~date
		)
	);

	// Martin Luther King, Jr. Day (3rd Monday in January)
	Date ( 1 ; 15 ; calendarYear )	// earliest possible date
	+ Choose ( DayOfWeek ( Date ( 1 ; 1 ; calendarYear ) ) - 1;
		1 ; 0 ; 6 ; 5 ; 4 ; 3 ; 2	// adjust for day of week of month start
	);

	// Washington's Birthday (3rd Monday in February)
	Date ( 2 ; 15 ; calendarYear )	// earliest possible date
	+ Choose ( DayOfWeek ( Date ( 2 ; 1 ; calendarYear ) ) - 1;
		1 ; 0 ; 6 ; 5 ; 4 ; 3 ; 2	// adjust for day of week of month start
	);

	// Memorial Day (last Monday in May)
	Date ( 5 ; 25 ; calendarYear )	// earliest possible date
	+ Choose ( DayOfWeek ( Date ( 5 ; 31 ; calendarYear ) ) - 1;
		0 ; 6 ; 5 ; 4 ; 3 ; 2 ; 1	// adjust for day of week of month end
	);

	// U.S. Independence Day (4 July)
	Let ( [
		~date = Date ( 7 ; 4 ; calendarYear );
		~day = DayOfWeek ( ~date )
	];
		Case (
			~day = 1 ; ~date + 1;	// following Monday
			~day = 7 ; ~date - 1;	// previous Friday
			/* Else */ ~date
		)
	);

	// Labor Day (1st Monday in September)
	Date ( 9 ; 1 ; calendarYear )	// earliest possible date
	+ Choose ( DayOfWeek ( Date ( 9 ; 1 ; calendarYear ) ) - 1;
		1 ; 0 ; 6 ; 5 ; 4 ; 3 ; 2	// adjust for day of week of month start
	);

	// Columbus Day (2nd Monday in October)
	Date ( 10 ; 8 ; calendarYear )	// earliest possible date
	+ Choose ( DayOfWeek ( Date ( 10 ; 1 ; calendarYear ) ) - 1;
		1 ; 0 ; 6 ; 5 ; 4 ; 3 ; 2	// adjust for day of week of month start
	);

	// Veterans Day (11 November)
	Let ( [
		~date = Date ( 11 ; 11 ; calendarYear );
		~day = DayOfWeek ( ~date )
	];
		Case (
			~day = 1 ; ~date + 1;	// following Monday
			~day = 7 ; ~date - 1;	// previous Friday
			/* Else */ ~date
		)
	);

	// Thanksgiving Day (4th Thursday in November)
	Date ( 11 ; 22 ; calendarYear )	// earliest possible date
	+ Choose ( DayOfWeek ( Date ( 11 ; 1 ; calendarYear ) ) - 1;
		4 ; 3 ; 2 ; 1 ; 0 ; 6 ; 5	// adjust for day of week of month start
	);

	// Christmas Day (25 December)
	Let ( [
		~date = Date ( 12 ; 25 ; calendarYear );
		~day = DayOfWeek ( ~date )
	];
		Case (
			~day = 1 ; ~date + 1;	// following Monday
			~day = 7 ; ~date - 1;	// previous Friday
			/* Else */ ~date
		)
	);

	// New Years Day (observed from next year)
	Let ( [
		~date = Date ( 1 ; 1 ; calendarYear + 1 )
	];
		If ( DayOfWeek ( ~date ) = 7 ; ~date - 1 /* Else, Null */ )
	)
)

This function returns a return-delimited list of the dates of observed holidays in the specified calendar year. This version of the function includes observed U.S. federal holidays. It should be modified to include any holidays observed by the users of each particular system.

Comments

		Geoffrey Gerhard, Creative Solutions Incorporated Nov 17, 2023
Juneteenth was added as a US Federal Holiday in 2021. Add this to the List function to include that holiday in the result... // Juneteenth (19 June) Let ( [ ~date = Date ( 6 ; 19 ; holidayYear ); ~day = DayOfWeek ( ~date ) ]; Case ( ~day = 1 ; ~date + 1; // following Monday ~day = 7 ; ~date - 1; // previous Friday /* Else */ ~date ) );

		John McElwain Jul 27, 2026
Thanks for this helpful function. I needed to add the friday after Thanksgiving and found a problem with the Thanksgiving calculation. If the start of the month falls on thursday, it was giving the date a week too early. Here the new calc and the calc for the day after as well... // Thanksgiving Day (4th Thursday in November) Date ( 11 ; 22 ; calendarYear ) // earliest possible date + Choose ( DayOfWeek ( Date ( 11 ; 1 ; calendarYear ) ) - 1; 4 ; 3 ; 2 ; 1 ; 7 ; 6 ; 5 // adjust for day of week of month start ); // Thanksgiving Friday (Friday following 4th Thursday in November) Date ( 11 ; 22 ; calendarYear ) // earliest possible date + Choose ( DayOfWeek ( Date ( 11 ; 1 ; calendarYear ) ) - 1; 5 ; 4 ; 3 ; 2 ; 8 ; 7; 6 // adjust for day of week of month start );

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

BusinessHolidays ( calendarYear )

Comments

Support this website.

Support this website.