RandomBeta ( alpha ; beta )

Returns random values from a Beta distribution

Average rating: 4.7 (29 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

List (
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 );
RandomBeta ( .5 ; .5 )
)

Sample output:

.46840777434408664703
.97474977374076843262
.65431562019512057304
.92274553608149290085
.96121877944096922874
.91257860092446208
.42773321550339460373
.92498611891642212868
.7081926506944000721
.45913609443232417107

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * RandomBeta ( alpha ; beta )
 *
 * PURPOSE:
 *		When called repeatedly, RandomBeta creates values consistent with a
 *		beta-distributed random variable with shape parameters alpha and beta.
 *
 * RETURNS:
 *		A number between 0 (zero) and 1 representing a random variate from a
 *		beta distribution with the specified parameters.
 *
 * PARAMETERS:
 *		alpha: A number, alpha > 0
 *		beta: A number, beta > 0
 *
 * DEPENDENCIES: none
 *
 * HISTORY:
 *		CREATED on 2010-02-22 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		http://en.wikipedia.org/wiki/Beta_distribution
 * =====================================
 */

Let ( [
	~guess = Random;

	~mode = ( alpha - 1 ) / ( alpha + beta - 2 );
	~densityAtMode =
		( ~mode ^ ( alpha - 1 ) )
		* ( ( 1 - ~mode ) ^ ( beta - 1 ) );

	~rejectionThreshold = //probability density at ~guess
		( ~guess ^ ( alpha - 1 ) )
		* ( ( 1 - ~guess ) ^ ( beta - 1 ) )
		* ~densityAtMode //maps function to [0,1] for max acceptance rate
];
	Case (
		alpha ≤ 0 or beta ≤ 0; //parameters out of range
			"?"; //error

		Random ≤ ~rejectionThreshold;
			~guess;

		//Else, reject ~guess and sample again
			RandomBeta ( alpha ; beta )
	)
)

When called repeatedly, RandomBeta creates values consistent with a beta-distributed random variable with shape parameters alpha and beta.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

RandomBeta ( alpha ; beta )

Comments

Support this website.

Support this website.