_Normsdist ( z )

FileMaker implementation of NORMSDIST Excel function

Average rating: 4.6 (28 votes) Log in to vote

Mislav Kos - Show more from this author
Soliant Consulting
https://www.soliantconsulting.com/

Sample input:

_Normsdist ( 5 )
_Normsdist ( 4 )
_Normsdist ( 3 )
_Normsdist ( 2 )
_Normsdist ( 1 )
_Normsdist ( 0.9 )
_Normsdist ( 0.7 )
_Normsdist ( 0.3 )
_Normsdist ( 0 )
_Normsdist ( -0.5 )
_Normsdist ( -1 )
_Normsdist ( -2 )
_Normsdist ( -3 )
_Normsdist ( -4 )
_Normsdist ( -5 )

Sample output:

0.999999713
0.999968314
0.998650033
0.977249938
0.841344741
0.815939909
0.758036422
0.617911358
0.500000001
0.308537532
0.158655259
0.022750062
0.001349967
3.17E-05
2.87E-07

Compare to Excel:
0.999999713
0.999968329
0.998650102
0.977249868
0.841344746
0.815939875
0.758036348
0.617911422
0.500000000
0.308537539
0.158655254
0.022750132
0.001349898
3.17E-05
2.87E-07

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * @SIGNATURE:
 * _Normsdist ( z )
 * 
 * @PARAMETERS:
 * z - The parameter for which the probability is calculated for.
 * 
 * @HISTORY:
 * Created: 2011-Aug-30 by Mislav Kos, Soliant Consulting
 * 
 * @PURPOSE: 
 * To provide a near equivalent of the NORMSDIST Excel function.
 * 
 * @RESULT:
 *  The probability that the observed value of a standard normal random variable will be less than or equal to parameter z.
 * 
 * @ERRORS:
 * N/A
 * 
 * @NOTES:
 * 
 * This custom function is a FileMaker implementation of the NORMSDIST function in Excel.
 * Caution: This custom function is ONLY AN APPROXIMATION of the Excel function; 
 * i.e. it will calculate an approximate answer rather than the exact answer.
 * (Note: The same is true of the Excel function.)
 * The results are accurate to several decimal places, which is typically sufficient for most uses.
 * 
 * Also see the custom function _Normdist ( z ; mu ; sigma ).
 * 
 * The difference between NORMDIST and NORMSDIST:
 *   - NORMSDIST applies to standard normal distribution.
 *   - NORMDIST applies to any normal distribution.
 *   - A standard normal distribution has a mean of 0 and a standard deviation of 1.
 * 
 * The calculation was adapted from http://www.wilmott.com/messageview.cfm?catid=8&threadid=78622.
 * 
 * Here are some notes on the NORMSDIST Excel function from http://support.microsoft.com/kb/827369: 
 *   - NORMSDIST(z) returns the probability that the observed value of a standard normal random variable will be less than or equal to z. 
 *   - A standard normal random variable has mean 0 and standard deviation 1 (and also variance 1 because variance = standard deviation squared).
 * 
 */


Let ( [ 
		
		b1 =     .31938153 	; 
		b2 =   -.356563782 	; 
		b3 =   1.781477937 	; 
		b4 = -1.821255978 	; 
		b5 =   1.330274429 	; 
		p  =      .2316419 	; 
		c  =      .39894228 	; 
		
		t = If ( 
				z ≥ 0 ; 
				1 / ( 1 + p * z ) ; 
				1 / ( 1 - p * z ) 
			) ;
		
		m = c * Exp ( -z * z / 2 ) * t * ( t * ( t * ( t * ( t * b5 + b4 ) + b3 ) + b2 ) + b1 ) 
		
	] ; 
	
	If ( z ≥ 0 ; 1 - m ; m ) 
	
)

PURPOSE:
To provide a near equivalent of the NORMSDIST Excel function.

RESULT:
The probability that the observed value of a standard normal random variable will be less than or equal to parameter z.

NOTES:
This custom function is a FileMaker implementation of the NORMSDIST function in Excel.
Caution: This custom function is ONLY AN APPROXIMATION of the Excel function;
i.e. it will calculate an approximate answer rather than the exact answer.
(Note: The same is true of the Excel function.)
The results are accurate to several decimal places, which is typically sufficient for most uses.

Also see the custom function _Normdist ( z ; mu ; sigma ).

The difference between NORMDIST and NORMSDIST:
- NORMSDIST applies to standard normal distribution.
- NORMDIST applies to any normal distribution.
- A standard normal distribution has a mean of 0 and a standard deviation of 1.

The calculation was adapted from http://www.wilmott.com/messageview.cfm?catid=8&threadid=78622.

Here are some notes on the NORMSDIST Excel function from http://support.microsoft.com/kb/827369:
- NORMSDIST(z) returns the probability that the observed value of a standard normal random variable will be less than or equal to z.
- A standard normal random variable has mean 0 and standard deviation 1 (and also variance 1 because variance = standard deviation squared).

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

_Normsdist ( z )

Comments

Support this website.

Support this website.