DateDif ( date1 ; date 2 ; flag )

Simulates Excel function of same name and provides for text labeling with correct grammer.

Average rating: 4.5 (35 votes) Log in to vote

Brett Buchmiller
No Company
http://filemaker.com

Sample input:

DateDif( 11/2/2006 ; 7/6/2011 ; "Y" )

DateDif( 11/2/2006 ; 7/6/2011 ; "T" )

DateDif( 11/2/2006 ; 7/6/2011 ; "LIST" )

Sample output:

4

4 years, 8 months and 4 days

4
8
4

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* 	Original algorithm © 2006 Winfried Huslik, www.fmdiff.com
	Modifications © 2011 Brett Buchmiller
	flag ; "Y" returns total years, "M" returns total months, "D" returns total days, "T" returns time as years, months days as text with correct grammer
	flag ; "LIST" returns return delimited list with y, m, d
	Values returned are completed integer units - rounded DOWN.
*/

Let ( [

	neg = Case ( date1 > date2 ; -1 ; 1 ) ;

	d1 = Case ( neg < 0 ; date2 ; date1 ) ;

	d2 = Case ( neg < 0 ; date1 ; date2 ) ;

	d = Mod ( Day ( d2 ) - Day ( d1 ) ; Day ( 
      Date ( Month ( d1 ) + 1 ; 0; Year ( d1 ) ) ) ) ;

	m = Mod ( Month ( d2 ) - Month ( d1 ) -
      ( Day ( d2 ) < Day ( d1 ) ) ; 12 ) ;

	y = Year ( d2 ) - Year ( d1 ) - ( ( Month ( d2 ) -
      ( Day ( d2 ) < Day ( d1 ) ) ) < Month ( d1 ) ) ; 

	yearlabel = If( y=1 ; y & " year" ; y & " years" ) ;

	monthlabel = If( m =1 ; m & " month" ; m & " months" ) ;

	daylabel = If( d=1 ; d  & " day" ; d & " days" )
  ];


Case(
	flag = "Y" ; y * neg ;
	flag = "M" ; m * neg + (y * 12 * neg) ;
	flag = "D" ; ( date2 - date1 ) * neg ;
	( flag = "T" ) ; 
		Case(
			( y ≠ 0 ) and ( m ≠ 0 ) and ( d ≠ 0 ) ; yearlabel & ", " & monthlabel & " and " & daylabel ;
			( y = 0 ) and ( m ≠ 0 ) and ( d ≠ 0 ) ; monthlabel & " and " & daylabel ;
			( y = 0 ) and ( m = 0 ) and ( d ≠ 0 ) ; daylabel ;
			( y = 0 ) and ( m = 0 ) and ( d = 0 ) ; "0 days" ;
			( y ≠ 0 ) and ( m = 0 ) and ( d ≠ 0 ) ; yearlabel & " and " & daylabel ;
			( y ≠ 0 ) and ( m ≠ 0 ) and ( d = 0 ) ; yearlabel & " and " & monthlabel ;
			( y ≠ 0 ) and ( m = 0 ) and ( d = 0 ) ; yearlabel ;
			( y = 0 ) and ( m ≠ 0 ) and ( d = 0 ) ; monthlabel ;
			"Undefined Date Text Layout!"
			) ;
	flag = "LIST" ; y * neg & "¶" & m * neg & "¶" & d * neg & "¶" ;	"Undefined Flag!"
	)
)

Based on the excellent algorithm by Winfried Huslik but adapted for multiple uses based on flag. Works similar to DateDif() function in excel where flag determines if returns years, months or days between dates. Additional flags allow for text string with proper grammer or list of values to be accessed by LeftValues(), MiddleValues() or RightValues.

Comments

		Daniele Raybaudi, ACI Aug 8, 2011
Hi what if a date is empty ?

		Daniele Raybaudi, ACI Aug 8, 2011
What about: ... d1 = Min ( date1 ; date2 ) ; d2 = Max ( date1 ; date2 ) ; ...

		DJ, NM Nov 3, 2014
Using the dates 02/01/2015 and 11/30/2015 returns the wrong result.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

DateDif ( date1 ; date 2 ; flag )

Comments

Support this website.

Support this website.