AssignWindowName ( Text )

Add " - num" to Text when the Text is not unique in WindowNames.

Average rating: 4.8 (30 votes) Log in to vote

Koji Takeuchi - Show more from this author
TonicNote, Inc.
https://tonicnote.com

Sample input:

AssignWindowName ( "Customer" )

Sample output:

"Customer - 2"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
AssignWindowName ( Text )
2011.05.18, Koji Takeuchi <takeuchi@nemoux.com>


description:
	Add " - num" to Text when the Text is not unique in WindowNames.
	Assumed this will use in script for changing layout and specifying window name.
ex.
	Text = text you're about to assign window name to current window.
			ex. "Customer"

	AssignWindowName ( "Customer" )
	 -> "Customer - 2" (When window exists which name has "Customer")
	 -> "Customer - 3" (When window exists which name has "Customer" and "Customer - 2")
	 -> "Customer - 3" (When window exists which name has "Customer - 2" and does not exists window "Customer")
	 -> "Customer - 2" (When window exists which name has "Customer" and "Customer - 2" and current window name is "Customer - 2")
*/

Let (
[
text_to_count = 
	Text ;
current_window_name = 
	Get ( WindowName ) ;
$$counter =
	$$counter + 1 ;
$$window_names =
	Case (
		not IsEmpty ( $$window_names ) ;
		$$window_names ;
		Substitute (
			¶ & WindowNames & ¶ ;
			¶ & current_window_name & ¶ ; ""
		) // Substitute
	) ; // Case
window_count = 
	ValueCount ( $$window_names ) ;
window = 
	GetValue ( $$window_names ; $$counter ) ;
$$max =
	Case (
		PatternCount ( window ; " - " ) and Exact ( text_to_count ; Left ( window ; Position ( window ; " - " ; 1 ; 1 ) - 1 ) ) ;
		Max ( $$max ; GetAsNumber ( Right ( window ; Length ( window - Position ( window ; " - " ; 1 ; 1 ) ) ) ) ) ;
		Exact ( text_to_count ; window ) ;
		Max ( $$max ; 1 ) ;
		$$max
	)
] ;

Case (
$$counter ≤ window_count ;
AssignWindowName ( text_to_count ) ;

Let (
[
result = 
	text_to_count &
	Case (
		$$max ≥ 1 ;
		" - " & $$max + 1
	) ;
$$counter = "" ;
$$window_names = "" ;
$$max = ""
] ;
result
) // Let

) // Case

) // Let

AssignWindowName ( Text )
2011.05.18, Koji Takeuchi

description:
Add " - num" to Text when the Text is not unique in WindowNames.
Assumed this will use in script for changing layout and specifying window name.
ex.
Text = text you're about to assign window name to current window.
ex. "Customer"

AssignWindowName ( "Customer" )
-> "Customer - 2" (When window exists which name has "Customer")
-> "Customer - 3" (When window exists which name has "Customer" and "Customer - 2")
-> "Customer - 3" (When window exists which name has "Customer - 2" and does not exists window "Customer")
-> "Customer - 2" (When window exists which name has "Customer" and "Customer - 2" and current window name is "Customer - 2")

Comments

		Dr_John, none Nov 16, 2019
You are a hard man to find. Your website has a problem.

		Koji Takeuchi, TonicNote, Inc. Nov 16, 2019
Hi, Dr_John. Are you saying about me, or Brian Dunning?

		Camberol Oct 28, 2020
This no longer seems to work in FM 19.1.2 Mac Shouldn't AssignWindowName ( Get ( WindowName ) ) be "WindowName - 1" The result on FM19 is WindowName.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

AssignWindowName ( Text )

Comments

Support this website.

Support this website.