ChaosDecrypt ( cipherText ; key )

Decrypt text enciphered by the ChaosEncrypt() function

Average rating: 4.1 (35 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

ChaosDecrypt ( "蔿괴㼀ኒጏ륮縤ᖙ㇤ヰꣿ톃鋦⛤簘" ; "The super-secret key" )

Sample output:

The original text

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * ChaosDecrypt ( cipherText ; key )
 *
 * WARNING:
 * Different versions of the ChaosEncrypt and ChaosDecrypt functions are
 * unlikely to be compatible.
 *
 * PURPOSE:
 * Uses chaotic permutations of the key to create an decrypted version of
 * cipherText that was created by the ChaosEncrypt() function. This function
 * uses a psuedo-chaotic stream cipher algorithm adapted to the constraints of
 * FileMaker custom functions.
 *
 * PARAMETERS:
 * cipherText: The text string to decrypt
 * key: The key to used to encrypt cipherText
 *
 * RETURNS:
 * A decrypted version of cipherText.
 *
 * NOTES:
 * This function has not been subjected to rigorous cryptanalysis, and the
 * author does not warranty the security of encrypted text.
 *
 * This is a recursive custom function, and hence is limited in the maximum
 * combined length of text and key that it can decrypt.
 *
 * HISTORY:
 * MODIFIED on 2011-01-23 by Jeremy Bante to account for composite
 * characters.
 * MODIFIED on 2011-01-14 by Jeremy Bante to use a different map and
 * systematically perturbed orbits.
 * MODIFIED on 2011-01-09 by Jeremy Bante to use a different chaotic
 * map that results in greater diffusion and faster calculation.
 * MODIFIED on 2011-01-05 by Jeremy Bante to use a different chaotic
 * map when transforming the key.
 * CREATED on 2011-01-04 by Jeremy Bante of The Support Group.
 *
 * REFERENCES:
 * ChaosDecrypt function: http://www.briandunning.com/cf/1259
 * ChaosEncrypt function: http://www.briandunning.com/cf/1258
 * ChaosHash function: http://www.briandunning.com/cf/1261
 * =====================================
 */
 
Case (
	/*First call to function; initialize variables*/
	not $~step;
	Let ( [
		$~keyLength = Length ( key );
		$~priorByte = 32749; //greatest prime < 2^15
		$~step = 1
	];
		ChaosDecrypt ( cipherText ; key )
	);

	/*Step 1, convert key to numbers and scramble first round*/
	$~step = 1;
	Let ( [
		//extract next byte from key, accounting for composite characters
		~keyByte = Code ( Left ( key ; 1 ) );
		~extraByte = Left ( ~keyByte ; Length ( ~keyByte ) - 5 );
		~keyByte = Mod ( Right ( ~keyByte ; 5 ) + $~priorByte ; 65535 );
		
		//iterate ~keyByte through the map 8x, perturb 4th orbits
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) + 1; 65535 );
		
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) + 1 ; 65535 ) + 1;
		
		//add new value to list
		$~key = List ( ~keyByte ; $~key );
		$~priorByte = ~keyByte;
		
		//continue until whole key is processed
		~keyLength = Length ( key );
		$~step = If ( ~keyLength > 1 ; $~step ; /*else*/ $~step + 1 )
	];
		ChaosDecrypt (
			cipherText;
			Char ( ~extraByte ) & Right ( key ; ~keyLength - 1 )
		)
	);
	
	/*Step 2, apply key to text*/
	$~step = 2;
	Let ( [
		~keyByte = Mod ( GetValue ( $~key ; 1 ) + $~priorByte ; 65535 );
		
		//iterate ~keyByte through the map 8x, perturb 4th orbits
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) + 1; 65535 );
		
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) ; 65535 );
		~keyByte = Mod ( 4099 * ( 65535 - ~keyByte ) + 1 ; 65535 ) + 1;
		
		//extract next byte from cipherText, accounting for composite characters
		~cipherByte = Code ( Left ( cipherText ; 1 ) );
		~extraByte = Left ( ~cipherByte ; Length ( ~cipherByte ) - 5 );
		~cipherByte = Right ( ~cipherByte ; 5 );
		
		//apply key to text
		//additive complement under 2^16 is analogous to XOR in binary encryption
		~plainByte = 65535 - Mod ( ~cipherByte + ~keyByte ; 65535 );
		$~plainText = $~plainText & Char ( ~plainByte );
		
		//rotate the key
		$~priorByte = ~cipherByte;
		$~key =
			Substitute (
				List ( RightValues ( $~key ; $~keyLength - 1 ) ; ~keyByte );
				"¶¶";
				"¶"
			);

		//continue until whole text is encrypted
		~textLength = Length ( cipherText );
		$~step = If ( ~textLength > 1 ; $~step ; /*else*/ $~step + 1 )
	];
		ChaosDecrypt (
			Char ( ~extraByte ) & Right ( cipherText ; ~textLength - 1 );
			""
		)
	);
	
	/*Step 3, clean-up and return result*/
	$~step = 3;
	Let ( [
		~plainText = $~plainText;
		
		//purge variables
		$~key = "";
		$~keyLength = "";
		$~plainText = "";
		$~priorByte = "";
		$~step = ""
	];
		~plainText
	)
)

Uses chaotic permutations of the key to create an decrypted version of cipherText that was created by the ChaosEncrypt() function. This function uses a psuedo-chaotic stream cipher algorithm adapted to the constraints of FileMaker custom functions.

This function has not been subjected to rigorous cryptanalysis, and the author does not warranty the security of encrypted text.

Newer versions of this function are very unlikely to be backwards compatible.

Comments

		Bob Stuart, Noosa, Queensland, Australia Jan 21, 2011
Nice work, Jeremy, but in encrypting and decrypting this text: PLEASE READ THIS LICENSE CAREFULLY BEFORE USING THIS SOFTWARE. BY USING THIS SOFTWARE, YOU AGREE TO BECOME BOUND BY THE TERMS OF THIS LICENSE. I could only get it to go this far: PLEASE READ THIS LICENSE CAREFULLY BEFORE USING THIS SOFTWARE. BY USING THIS SOFTWARE, YOU AGREE TO BECOME BOUND BY THE TERMSèº í‹—á£ è¾¶é§‰é§“é¦ é§Œé§‰é§ƒé§…é§Žé§“é§…é¦® If it could Encode/Decode a larger chunk, it would be REALLY useful to me. Regards, Bob Stuart Think Data Noosa Queensland Australia. bobstu@thinkdata.com.au

		Jeremy Bante, San Mateo, CA, USA Jan 21, 2011
It looks like you found a bug in the creation of the decryption keystream. Thank you for catching this. I'll look in to it this weekend, and let you know when I have it fixed.

		Jeremy Bante, San Mateo, CA, USA Jan 23, 2011
Fixed it! It turned out to be a problem with handling composite characters, and didn't have anything to do with the length at all.

		Olly, London, UK Jan 25, 2011
Very cool. Esp for FMGO. Thanks for these Jeremy.

		P Sanchez, Jacksonville, FL May 17, 2011
encryption works well. When I use the decryption using the same key, I get this...çˆµ any ideas?

		Jeremy Bante, San Mateo, CA May 17, 2011
Would you be willing to send me the original text and your key, so I can take a closer look at it? http://scr.im/jbantetsg

		P Sanchez, Jacksonville, FL May 17, 2011
just a made up SSN# 001-22-3333 and the key was 10 (record ID). I was just testing this in the script, so I kept it real simple.

		P Sanchez, Jacksonville, FL May 17, 2011
I should specify that the script is basically, set variable of $value; ChaosDecrypt and then a set field step to set this $value into my field.

		Jeremy Bante, San Mateo, CA, USA May 17, 2011
So are you encrypting "SSN# 001-22-3333", "001-22-3333", or "001223333"? I wont get a chance to look into this until tonight, but I'll let you know what I find and update this page with any fix I come up with.

		Paula Sanchez, JACKSONVILLE May 17, 2011
Yep. I tried both with and without the dashes. Neither worked on the decryption. Not sure if I am doing something wrong or not...

		Jeremy Bante, San Mateo, CA, USA May 23, 2011
For the public record, Paula and I looked into the issue, and it turned out that there was nothing wrong with the function.

		Brian Donovan, Mexico Feb 21, 2015
very good code! excellent! found no bugs will post if I do!

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ChaosDecrypt ( cipherText ; key )

Comments

Support this website.

Support this website.