CF_HTMLtoFMP_styledText ( text ; num )

Converts data between predefined HTML tags into FMP bold / italic etc. As well as standard HTML tags, you can also define your own custom tags.

Average rating: 3.9 (52 votes) Log in to vote

Chaim Bacon - Show more from this author
SeekUnique
http://www.seekunique.co.uk

Sample input:

Bold text
Italic text
put this in caps

This text will show in 24pt

Sample output:

Bold text
Italic text
PUT THIS IN CAPS
This text will show in 24pt

(It is unlikely the sample output text will display formatted on this website. However it does in FMP)

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
This custom function converts data between PREDEFINED HTML TAGS into FMP bold, italic, underline, h1, h2, h3, bullet points etc.

- HTML start and end tags must be defined in the 'tags' variable.
- The FMP functions to replace the tags must be defined in the 'replaceWith' variable.
- Any open tags that have no corresponding close tag, e.g. <br>, must be defined at the end of this custom function.

You can also add your own tags.

NOTE: The other custom function 'CF_HTMLtoFMP_styledText_sub' is required for this one to work.

PARAMETERS:
'text' is the original HTML text
'num' should always be 1 when calling this custom function (it defines which tag is replaced first)

Created by Chaim Bacon
SeekUnique Software Ltd.
chaim@seekunique.co.uk
+44 (0)1923 944 444
*/


Let ([

// Define your tags here. All tags defined here must have both and opening and closing tag separated by a pipe character
tags = "<b>|</b>¶<i>|</i>¶<u>|</u>¶<p>|</p>¶<q>|</q>¶<em>|</em>¶<h1>|</h1>¶<h2>|</h2>¶<h3>|</h3>¶{|}" ; 
tag = GetValue ( tags ; num ) ; 
openTag = Left ( tag ; Position ( tag ; "|" ; 1 ; 1 ) - 1 ) ; 
closeTag = Middle ( tag; Position ( tag ; "|" ; 1 ; 1 ) + 1 ; 99 ) ; 
$quote = "\""  ; 

// Define the FMP native code that will be used to replace each HTML tag...
// Add your own replacement code here
// Note: The value of $text is both defined and evaluated in the subordinate custom function. It is just used as a placeholder here.

replaceWith = Case ( 
 openTag = "<b>" ; "TextStyleAdd ( $text ; Bold )" ; 
 openTag = "<i>" ; "TextStyleAdd ( $text ; Italic )" ; 
 openTag = "<u>" ; "TextStyleAdd ( $text ; Underline )" ; 
 openTag = "<p>" ; "\¶&" & "$text" & "&\¶"  ;  
 openTag = "<q>" ; "$quote & $text & $quote" ; 
 openTag = "<em>" ; "Upper ( $text )" ; 
 openTag = "<h1>" ; "TextSize ( $text ; 24 )" ; 
 openTag = "<h2>" ; "TextSize ( $text ; 20 )" ; 
 openTag = "<h3>" ; "TextSize ( $text ; 16 )" ; 

// You can also include your own custom tags, so if all text between {} curly brackets needs to be in red and bold...
 openTag = "{" ; "TextColor ( TextStyleAdd ( $text ; Bold ) ; RGB ( 200 ; 20 ; 20 ) )" ; 
 );

modText = CF_HTMLtoFMP_styledText_sub ( text ; openTag ; closeTag ; replaceWith )

]; 

Case( num ≤ ValueCount ( tags ) ; 
CF_HTMLtoFMP_styledText ( modText ; num + 1 ) ; 

// Define below any single tags, i.e. open tags that have no close tags, e.g. <br>
// You can also include tags which may have been used above but where the closing tag is often left out, e.g. <p>
Substitute ( modText ; 
   ["<br>" ; "¶"] ; 
   ["<p>" ; "¶"] ; 
// Transformations
   [ "<li>" ; "¶• " ] ;
   [ "<li " ; "¶• " ] ;
//Tabs, spaces, returns etc.
   [ "	" ; " " ] ; // tab character
   [ "     " ; " " ] ;
   [ "    " ; " " ] ;
   [ "   " ; " " ] ;
   [ "  " ; " " ] ;
   [ " ¶" ; "¶" ] ;
   [ "¶ " ; "¶" ] ;
//Other characters, e.g. encoded characters
   [ "%20" ; " " ] ; // encoded space
   [ "%22" ; "\"" ] // encoded double quotation mark
)


) // close case

) // close let

See description in custom function above.

NOTE: The other custom function 'CF_HTMLtoFMP_styledText_sub' is required for this one to work.

You can download a fully working sample file of this function at:
https://www.dropbox.com/s/slkfotd4wtlyxpq/HTML_to_FM_Styled_Text.fmp12?dl=0

Comments

		Daniel H., Pasadena, CA Sep 20, 2015
Does not seem to work, just returns a ? for me when used in 14.

		Chaim, Bacon Sep 21, 2015
Hi Daniel, did you also install the other custom function. There is a note on the page, just above your comment, that says, "NOTE: The other custom function 'CF_HTMLtoFMP_styledText_sub' is required for this one to work." I have tested it in FMP 14 - with the subordinate function - and it works fine. Please download the sample file (there is a link above).

		Kyle Williams, Augusto Digital Dec 23, 2020
FYI: Your sample file link no longer works...

		Mark D Kerr, Discovery Reef Design & Consulting Jul 28, 2021
I'd be thrilled to see the demo, but the old link is no longer valid.

		Chaim Bacon, SeekUnique Jul 28, 2021
Hi Mark, I have made a new sample file and it works as expected way back when it was written in 2008. Tested on Mac with FM 19 but can't see why it wouldn't work on Win or any recent version of FM. Please use this link to download: https://www.dropbox.com/s/slkfotd4wtlyxpq/HTML_to_FM_Styled_Text.fmp12?dl=0

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CF_HTMLtoFMP_styledText ( text ; num )

This text will show in 24pt

Comments

Support this website.

Support this website.