GetTextStyle ( text )

Get text formatting assigned to a field or text

Average rating: 4.3 (28 votes) Log in to vote

Marco Terrile - Show more from this author
ChefMaTe
http://www.chefmate.it

Sample input:

GetTextStyle ("a text formatted as Verdana 14 bold, italic, underline and red")

Sample output:

Verdana
14
bold+italic+underline
14483456

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* 
CF  GetTextStyle  v.0.1  Marco terrile 2006

WARNING: Requires two other Custom Functions

GetProperty ( propertyList ; propertyName )
by Shaun Flisakowski
and
HexToRGB ( Hex ; RGorB ) 
by Jeremiah Small

*/

Let (
[
text = GetAsCSS ( text ) ; 
start = Position ( text ; "\"" ; 1 ; 1 )+1 ; 
len = Position ( text ; "\"" ; 1 ; 2 ) - start ;
string = Substitute ( Substitute ( Middle ( text ; start ; len ); ";" ; "¶"); ":"; "=") ;
font =  Substitute ( GetProperty ( string ; "font-family" ); "'"; "");
size = GetAsNumber ( GetProperty ( string ; "font-size" ));
color =  HexToRGB ( GetProperty ( string ; "color" ); 0 );
weight = GetProperty ( string ; "font-weight" );
style = GetProperty ( string ; "font-style" );
deco = GetProperty ( string ; "text-decoration" );
variant = GetProperty ( string ; "font-variant" );
vertal = Trim ( GetProperty ( string ; "vertical-align" ));
spacing = Trim ( GetProperty ( string ; "letter-spacing" ))
]
;
font & "¶" & 
size & "¶" &
Substitute(
  Substitute(
     Substitute(
          If( not IsEmpty(weight); weight & "+")  &
          If( not IsEmpty(style) ; style & "+")  &
          If( not IsEmpty(deco) ; deco & "+")  & 
          If( not IsEmpty(variant) ; Substitute ( variant; "-"; "") & "+")  &
          If( not IsEmpty(vertal) ; Case ( vertal = "text-top"; "superscript"; vertal = "text-bottom"; "subscript" ) & "+")  &
          If( not IsEmpty(spacing) ; Case ( spacing = "-2px"; "condense"; spacing = "2px"; "extend" ) )  & "¶"
       ; "+¶"; "¶")
  ; "normal+"; "")
; "none+" ; "")
& color
)

Sintax: GetTextStyle ( text )

Parameter: "text" = any text expression or text field formatted with colors and styles other than default formatting of the field.

Result:
Font, Size, Style and RGB Color (only first style encountered by funcrion GetAsCSS) as "¶" separated list. Style is returned as "bold+italic+underline"... ecc. Color is returned as RGB number. If no formatting is applied the corresponding value is empty.
Warning, are returned only formatting other than the default ones of the field.

Example:
Let's say you have a field formatted as Arial 12 plain, black. If IN BROWSE MODE you change text formatting in - Verdana 14 bold, italic, underline, red - the CF returns:

Verdana
14
bold+italic+underline
14483456

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetTextStyle ( text )

Comments

Support this website.

Support this website.