HighlightWords ( theText ; searchString ; start ; range )

Formats occurences of searchString within theText to look like the results of a Google search!

Average rating: 4.2 (32 votes) Log in to vote

Ryan Brandys - Show more from this author
Branmuffin Industries
http://www.branmuffinindustries.com

Sample input:

HighlightTitleWords ( "
The Bricklin years were an important chunk of my life because I invested all the equity I had and lost it. It taught me things, like humility.

DeLorean spent eight years doing what took us two years, spent US$200 million or more doing it, and failed. He certainly had more credentials than us. Building a car company to build one car--I don't recommend it as a good investment." ; "delorean" ; 1 ; 40 )

Sample output:

Title: Malcolm Bricklin , By: Holloway, ... t. It taught me things, like humility. DeLorean spent eight years doing what took us tw ...

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//   this function returns the text string in a summarized format where an elipsis (...) is inserted to remove portions of the text
//   where the search string does not appear.
// the position function is not case-sensitive.

Let (  [
                        $lengthOfThisChunk = Length ( theText ) ;
                        $lengthOfSearchString = Length ( searchString ) ;
                        $positionOfNextOccurance = Position ( theText ; searchString ; 1 ; 1 )  // stores the char position of the first occurence of searchString, or 0 for not found
         ]   ;  "" ) &

If ( $lengthOfThisChunk = 0 
;               // recursion ending condition. 
          ""    // if theText is empty, return nothing. 

;               // else theText has something, so do the calc for this string and possibly recursive calc. 

    If ( $positionOfNextOccurance = 0 
     ;         // there is text in theText but there are no remaining occurences of searchString in the remaining theText
 
              If (   Length  (         theText      )  < 2 * range          // if the last bit of text is short enough
              ;                                                                             // then there is no need to ellipsisize the text. 
                     theText
              ;                                                                             // otherwise, shorten it and add a final ellipsis at the end of the text. 
                      Left  (   theText    ;  range  )   & " ..." 
              )                                                                              // dealt with the final bit of text and does not recur. 

     ;       // there is an occurence to work with, we will recur again.
 
             Let (  [
                                        $textBeforeOccurence = Left     ( theText ; $positionOfNextOccurance - 1 )          ;
                                        $textOfOccurence       = Middle ( theText ; $positionOfNextOccurance ; $lengthOfSearchString )    ;
                                        $textAfterOccurence   = Right   ( theText ; $lengthOfThisChunk - $lengthOfSearchString - $positionOfNextOccurance + 1) 
                     ]   ;  "" ) &

              If (   Length  (             $textBeforeOccurence          )  < 2 * range    // if the bit before the occurence is short enough
              ;                                                                                                     //  then there is no need to ellipsisize the text. 
                     $textBeforeOccurence 
              ;                                                                                                     // otherwise, ellipsisize the text
                      Left ( $textBeforeOccurence; range ) & " ... " & Right ( $textBeforeOccurence ; range ) 
              )
             & 
              TextStyleAdd(  $textOfOccurence    ; Bold )  // show the occurence as it appeared in the text
             &   
              HighlightWords ( $textAfterOccurence ; searchString ; 1;  range ) // and recur to the next iteration
      )
)

// Position(   text  ;  searchString  ;  start  ;  occurrence)
// Middle(    text  ;  start  ;  numberOfCharacters)

This script is designed to transform theText to mimic the results of a google search for searchString.

Occurences of searchString are Boldened, and if the occurences are very far apart, the text between them is shortened with an ellipsis (...)

You provide the function with:

theText ( a block of text or an article )
searchString ( the phrase you are searching for)
start ( use 1 to begin at the beginning of theText)
range ( the number of characters between occurences before an ellipsis is used )

And it provides you with a shorter block of text that looks like it came from your own private google search of your filemaker records.

Notes: This function is recursive. This function is not case-sensitive because most users would want all occurences of the searchString to appear regardless of case.

I highly recommend calling this function as shown below. this will remove extra carriage returns and turn the text black.

TextColor (

Substitute (

HighlightWords ( theText ; searchString ; 1; 40 )

; ¶ ; " " )

; RGB ( 0;0;0 ) )

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HighlightWords ( theText ; searchString ; start ; range )

Comments

Support this website.

Support this website.