ValueIndexByPosition ( valueList, searchValue, matchCase, occurrence, positionLCR )

Retrieve the index of the value in valueList containing the matching searchValue.

Be the first to rate this function Log in to vote

Lewis Lorenz - Show more from this author
Lorenz Companies
http://www.LorenzCom.com

Sample input:

ValueIndexByPosition ( "Alpha¶Bravo¶Charlie¶Echo", "charl", False, 1, "L" )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

While ( [ 
	~just = If ( IsEmpty ( positionLCR ) ; "L" ; Left ( positionLCR ; 1 ) );
	~list = Case ( ~just = "L" ; ¶ & valueList ; ~just = "R" ; valueList & ¶ ; valueList ) ;
	~value = Substitute ( searchValue ; ¶ ; "" );
	~value = Case ( ~just = "L" ; ¶ & ~value ; ~just = "R" ; ~value & ¶ ; ~value ) ;
	~occ = GetAsNumber ( occurrence );
	~pos = 0;
	~start = If ( ~occ < 0 ; Length ( ~list ) ; 1 );
	~ismatch = False;
	~index = 0
	]; 

		GetAsBoolean ( ~occ );

	[
	// Continue searching for one at a time until pos is 0 then change occ to 0 to exit while.
	~pos = If ( ~occ = 0 ; 0 ; Position ( ~list ; ~value ; ~start ; If ( ~occ < 0 ; -1 ; 1 ) ) );

	// Get index of found valueString in valueList.
	~index = If ( ~pos ; ValueCount ( Left ( ~list ; ~pos ) ) ; 0 );

	// Match testing.
	~ismatch = Exact ( Middle ( ~list ; ~pos ; Length ( ~value ) ) ; ~value );

	// Adjust where to begin looking for next ~value in ~list.
	~start = ~pos + If ( ~occ < 0 ; -1 ; 1 );

	// Adjust occurrence toward 0. If pos = 0 then set to 0. If matchCase then adjust only if is matched, else adjust all. 
	~occ = Case ( 
		~pos = 0 ; 
			0 ; 
		GetAsBoolean ( matchCase ) ; 
			If ( ~ismatch ; ~occ + If ( ~occ > 0 ; -1 ; 1 ) ; ~occ ) ; 
		~occ + If ( ~occ > 0 ; -1 ; 1 ) 
		)

	];

	~index

)

/* 
ValueIndexByPosition ( valueList, searchValue, matchCase, occurrence, positionLCR ) 

by Lewis C. Lorenz.

1/10/2024: UPDATED. 

Retrieve the index of the value in valueList containing the matching searchValue. Returns 0 if not found.
Toggle case-sensitive searching by passing a boolean through matchCase. 
Search for specific searchValue occurrence. A negative occurrence number causes backward search from the end of the valueList.
Specify whether to match the searchValue from the Left, Center ( middle ) , or Right within the value.

NOTICE: Requires FileMaker Pro 18+.

Examples: 
ValueIndexByPosition ( "Alpha¶Bravo¶Charlie¶Echo", "charl", False, 1, "L" ) = 3
ValueIndexByPosition ( "Alpha¶Bravo¶Charlie¶Echo", "charlie", True, 1, "L" ) = 0
ValueIndexByPosition ( "Daniel¶Danny¶Bill¶daniel¶Frank¶daniel¶Ed", "aniel", True, -2, "R" ) = 4
ValueIndexByPosition ( "Daniel¶Danny¶Bill¶daniel¶Frank¶daniel¶Ed", "an", False, -2, "C" ) = 5
*/

ValueIndexByPosition ( valueList, searchValue, matchCase, occurrence, positionLCR )

Retrieve the index of the value in valueList containing the matching searchValue. Returns 0 if not found.
Toggle case-sensitive searching by passing a boolean through matchCase.
Search for specific searchValue occurrence. A negative occurrence number causes backward search from the end of the valueList.
Specify whether to match the searchValue from the Left, Center ( middle ) , or Right within the value.

NOTICE: Requires FileMaker Pro 18+.

Examples:
ValueIndexByPosition ( "Alpha¶Bravo¶Charlie¶Echo", "charl", False, 1, "L" ) = 3
ValueIndexByPosition ( "Alpha¶Bravo¶Charlie¶Echo", "charlie", True, 1, "L" ) = 0
ValueIndexByPosition ( "Daniel¶Danny¶Bill¶daniel¶Frank¶daniel¶Ed", "aniel", True, -2, "R" ) = 4
ValueIndexByPosition ( "Daniel¶Danny¶Bill¶daniel¶Frank¶daniel¶Ed", "an", False, -2, "C" ) = 5

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValueIndexByPosition ( valueList, searchValue, matchCase, occurrence, positionLCR )

Comments

Support this website.

Support this website.