RemoveValues ( ValueList ; ValuesToRemove )

Remove a list of values from another list ( doesn't use While() so pre Fm18 safe )

Average rating: 5.0 (1 vote) Log in to vote

Nat Robinson - Show more from this author
Beezwax

Sample input:

RemoveValues ( "A¶B¶C¶D¶E¶F¶G" ; "F¶B" )

Sample output:

"A¶C¶D¶E¶G"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

If (
	ValueCount( ValuesToRemove ) = 0 ; 
		// If you pass a blank value or we are at the end of recursion, return the valueList passed
		ValueList ;
	Let ([	
		// Otherwise isolate the first valueToRemove, remove it from the valueList, and recurse the result with the remainingValuesToRemove 
		~valueToRemove = GetValue(ValuesToRemove; 1 ) ;
		~valuesToRemoveCount = ValueCount(ValuesToRemove) ;
		~remainingValuesToRemove = MiddleValues(ValuesToRemove; 2; ~valuesToRemoveCount - 1 ) 
	] ;
		If(
			IsEmpty( ~valueToRemove) ; 
				// If the ~valueToRemove is an empty row, just recurse on to the next valueToRemove
				RemoveValues( ValueList ; ~remainingValuesToRemove) ;
			Let([  
				// double up ("pad") the existing carriage returns within the list
				~valueList = Substitute ( ValueList ; "¶" ; "¶¶" );
				// remove the padded ValueToRemove from the padded list 
				~valueList = Substitute ( ¶ & ~valueList & ¶; ¶ & ~valueToRemove & ¶; "" ) ;
				// un-pad the double carriage returns within the list
				~valueList = Substitute ( ~valueList ; "¶¶" ; ¶ );
				// remove the bracketed carriage returns (a result of substitute line )
				~valueList = Middle ( ~valueList ; 2 ; Length ( ~valueList ) - 2 )

			] ;
				RemoveValues( ~valueList ; ~remainingValuesToRemove)
			)
		)
	)
)

Filters a list by using another list of values to remove. Not order-dependent, removes each value separately. Will protect any leading carriage returns or internal double carriages. This list of valuesToRemove is not order-dependent. Made it recursive so it would be Pre Fm 18 safe.

Comments

		Jack Ferret, Bel Covo Jun 15, 2020
This is exactly what I was looking for, but... RemoveValues ( "AÂ¶BÂ¶CÂ¶DÂ¶EÂ¶FÂ¶G" ; "FÂ¶B" ) ACTUALLY RETURNS: "AÂ¶CÂ¶DÂ¶EÂ¶G" (contrary to the currently-listed sample output), removing all instances of 'F' and 'B' from the list entirely. Like I said, exactly what I needed, so thank you.

		Nat Robinson, Beezwax Jun 16, 2020
Ha! I posted in hasted excitement. I've updated the sample output result in the description. Thanks for catching that and letting me know, Jack.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

RemoveValues ( ValueList ; ValuesToRemove )

Comments

Support this website.

Support this website.