TimeFormatAsText ( theTime )

Formats a valid time value to be written out in long form with the words for how many

Average rating: 4.7 (6 votes) Log in to vote

Jonathan Mickelson - Show more from this author

Sample input:

TimeFormatAsText ( GetAsTime ("1:27:02") )

Sample output:

1 hour, 27 minutes and 2 seconds

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* =============================== 
FUNCTION:   TimeFormatAsText ( theTime )
INPUT:      theTime - a valid FileMaker Time
OUTPUT:     A text string with the words for how many "hours, minutes and seconds" the time is:
            ex.  1:27:02 = "1 hour, 27 minutes and 2 seconds."
BY:         Jonathan Mickelson
=============================== */
// SHORT CIRCUIT FOR NO INPUTS
Case ( not IsEmpty ( theTime ) ;
Let ( 
[ 
// INPUT 
t = GetAsTime ( theTime ) ;
h = Hour ( t ) ; 
m = Minute ( t ) ; 
s = Seconds ( t ) ; 

// PREFS
pref_Punctuation = False ;   // SET IF ENDING PUNCTUATION IS NEEDED
punctuation = Case ( GetAsBoolean ( pref_Punctuation ) = True ; "." ) ; 

// STATIC TEXT (LOCALIZE HERE)
hr = "hour" ; 
hrs = "hours" ;  
min = "minute" ; 
mins = "minutes" ; 
sec = "second" ; 
secs = "seconds" ; 
t_And = "and" ; 

// FORMATTED TIME SECTIONS - SINGULAR OR PLURALIZED
t_Hours = 
        Case ( 
                  h = 1 ; h & " " & hr ; 
                  h > 1 ; h & " " & hrs
                  )  ; 
t_Minutes = Case ( 
                  m = 1 ; m & " " & min ; 
                  m > 1 ; m & " " & mins 
                 )  ; 
t_Seconds =  Case ( 
                 s = 1 ; s & " " & sec  ; 
                 s > 1 ; s & " " & secs  
                 ) ; 
// FINAL RESULT CALC
result = 
   t_Hours &   // XX HOURS
           Case ( 
                    h > 0 and m > 0 and s > 0 ;  
                    ", " ; // APPEND COMMA FOR LIST OF THREE VALUES
                    h > 0 and m > 0 ;
                    " " & t_And & " " ; // APPEND " AND " IF FINAL TWO VALUES
                  )

& t_Minutes & // XX MINUTES
           Case ( 
                   ( h > 0 or m > 0 ) and s > 0 ;
                    " " & t_And & " " // APPEND " AND " IF FINAL TWO VALUES
                  )
& t_Seconds & // XX SECONDS
           Case ( 
                    h > 0 or m > 0 or s > 0 ; 
                    punctuation // APPEND ENDING PUNCTUATION, IF PREF IS SET
                   ) 
] ; 
result
 )     // END LET
)  // END CASE

Formats a valid time value to be written out in long form with the words for how many "hours, minutes and seconds" the time value is. The output is in a format suited for duration rather than a time of day.

Comments

		Bruce Robertson Nov 23, 2017
Why is the example input RectangleArea ( 2 , 3 )? Why is the example output 6?

		Jonathan Mickelson Nov 25, 2017
Thanks for pointing that out Bruce, I missed some of the form fields when submitting it. It's been corrected, with a real example.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TimeFormatAsText ( theTime )

Comments

Support this website.

Support this website.