CreditCardType ( CreditCardNumber )

Returns Credit Card Type: Visa, MC, AmEx, Discover, China UnionPay. Supports 13-19 digit numbers.

Average rating: 3.5 (2 votes) Log in to vote

Will Loving - Show more from this author
Dedication Technologies, Inc.
http://studioschoolpro.com

Sample input:

CreditCardType( 5128351752976780 )
CreditCardType( 6222170397307260323 ) [19-digit number]
CreditCardType( 4026757339553700 )
CreditCardType( 370793488154818 )

Sample output:

MasterCard
China UnionPay
Visa
American Express

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
Update: 2019-03-18  -  This version reflects new brands card number ranges for Mastercard, China UnionPay, China T-Union and others. It handles the newer 17-19 digit numbers as well as older 13-14 digit ones.  For current card number ranges and brands, see http://en.wikipedia.org/wiki/Payment_card_number for current ranges.

This is a revison of Geoff Well's implementation of Brian Dunning's Card Validator. 
It requires that the 3 Luhn custom functions - Luhn, LuhnDoubleEven, LuhnProduct - available at 
http://www.briandunning.com/filemaker-custom-functions/
 per Wikipedia bank card number page, the most frequently updated public resource on this data. 
https://en.wikipedia.org/wiki/Payment_card_number#Issuer_identification_number_.28IIN.29

The following discontinued brands have been removed: Bankcard, Diners Club enRoute, Laser, Solo, Switch. I have also removed the detailed breakdown of various Visa cobrands such as Electron, Visa Purchasing, etc. Please reports any errors or suggested improvements in the comments at briandunning.com.

To obtain the Issuing Bank and type of card (debit or credit) for a specific BIN / IIN (Bank Identification Number / Issuing Institution Number), use the binlist.net online service 
*/


Let ( [

justNumbers = Filter( CreditCardNumber ; "0123456789" ) ; // remove any non-numeric characters

valid = Luhn ( justNumbers ) ] ; // end let variable definition

// begin calculation

If ( valid  and Length( justNumbers ) >= 13 and Length( justNumbers ) <= 19 ; 

Case(

Left(justNumbers;2) ="34"; "American Express";
Left(justNumbers;2) ="37"; "American Express";

Left(justNumbers;2) ="31" ; "China T-Union" ;

Left(justNumbers;2) ="62" or Left(justNumbers;2) ="81" or Left(justNumbers;2) ="88" ; "China UnionPay"; 

GetAsNumber(Left(justNumbers;3)) >= 300  and GetAsNumber(Left(justNumbers;3)) <= 305; "Diners Club";
Left(justNumbers;3) ="309" or Left(justNumbers;2) ="36"  or Left(justNumbers;2) ="38"  or Left(justNumbers;2) ="39" ; "Diners Club";

Left(justNumbers;4) ="6011" or Left(justNumbers ; 2 ) = 65 ; "Discover" ;
GetAsNumber(Left(justNumbers;6)) >= 622126  and GetAsNumber(Left(justNumbers;6)) <= 622925 ; "Discover";
GetAsNumber(Left(justNumbers;3)) >= 644  and GetAsNumber(Left(justNumbers;3)) <= 649 ; "Discover";

Left(justNumbers;2) ="60" or Left(justNumbers;2) ="6521"  or Left(justNumbers;2) ="6522" ; "RuPay" ;

Left(justNumbers;3) ="636" ; "InterPayment" ;

GetAsNumber(Left(justNumbers;3)) >= 637  and GetAsNumber(Left(justNumbers;3)) <= 639; "InstaPayment" ;

GetAsNumber(Left(justNumbers;4)) >= 3528  and GetAsNumber(Left(justNumbers;4)) <= 3589; "JCB";


Left(justNumbers;4) ="5019" ; "Dankort" ;
// All other Dankort cards are Visa cobranded)

GetAsNumber(Left(justNumbers;4)) >= 2200  and GetAsNumber(Left(justNumbers;4)) <= 2204; "MIR";

GetAsNumber(Left(justNumbers;2)) >= 51  and GetAsNumber(Left(justNumbers;2)) <= 55; "MasterCard";
GetAsNumber(Left(justNumbers;4)) >= 2221  and GetAsNumber(Left(justNumbers;4)) <= 2720; "MasterCard";

GetAsNumber(Left(justNumbers;6)) >= 506099  and GetAsNumber(Left(justNumbers;6)) <= 506198; "Verve";
GetAsNumber(Left(justNumbers;6)) >= 650002  and GetAsNumber(Left(justNumbers;6)) <= 650027; "Verve";

Left(justNumbers;2) ="50"; "Maestro";
GetAsNumber(Left(justNumbers;2)) >= 56  and GetAsNumber(Left(justNumbers;2)) <= 69; "Maestro";
Left(justNumbers;1) ="6"; "Maestro";

GetAsNumber(Left(justNumbers;6)) >= 979200  and GetAsNumber(Left(justNumbers;6)) <= 979289; "Troy";

Left(justNumbers;1) ="4"; "Visa";

Left(justNumbers;1) ="1"; "UATP";



"?" // unknown card
) // end case
 ; "Invalid Card Number" ) // end if
) // end let

Updated: 2019-03-18 - This version includes new brands and updated card number ranges for Mastercard, UnionPay and others. It also handles new 17-19 numbers as well as older 13-14 digit numbers. For current card number ranges and brands, see http://en.wikipedia.org/wiki/Payment_card_number for current ranges.

This is a revison of Geoff Well's implementation of Brian Dunning's Card Validator.
It requires that the 3 Luhn custom functions - Luhn, LuhnDoubleEven, LuhnProduct - available at
http://www.briandunning.com/filemaker-custom-functions/

The following discontinued brands have been removed: Bankcard, Diners Club enRoute, Laser, Solo, Switch. I have also removed the detailed breakdown of various Visa cobrands such as Electron, Visa Purchasing, etc. Please reports any errors or suggested improvements in the comments at briandunning.com.

To obtain the Issuing Bank and type of card (debit or credit) for a specific BIN / IIN (Bank Identification Number / Issuing Institution Number), use the binlist.net online service

Comments

		Lee Smith May 6, 2017
I think you need to add your Parameter to the name. i.e. CreditCardType (CreditCardNumber). Because FileMaker is looking for CreditCardNumber as a parameter. When I use the Clip Manager link, Clip Manager, provides reditCardTyp as the Parameter, which then has top be changed to CredCardNumber. Lee

		Will Loving, Dedication Technologies, Inc. May 6, 2017
Thanks Lee. Should read correctly now.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CreditCardType ( CreditCardNumber )

Comments

Support this website.

Support this website.