CurrencyFlex ( Input )

Currency format requiring at least two but allowing more decimals and keeps trailing zeros. Useful for "Each" or Unit pricing that cannot be rounded and may involve fractions of pennies that should be displayed as formatted currency which FM cannot do.

Average rating: 5.0 (4 votes) Log in to vote

Karl Ermatinger - Show more from this author
Industrial Control
http://www.industrialcontrol.com

Sample input:

CurrencyFlex ( 1 )
CurrencyFlex ( 1.1 )
CurrencyFlex ( 1.111 )
CurrencyFlex ( 1.100 )
CurrencyFlex ( 1.1001000 )
CurrencyFlex ( 1234567.100 )
CurrencyFlex ( -1.100 )
CurrencyFlex ( 1- )
CurrencyFlex ( 1..123 )
CurrencyFlex ( 123.45.678 )

Sample output:

$1.00
$1.10
$1.111
$1.100
$1.1001000
$1,234,567.100
$-1.100
$-1.00
?
?

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//
// CurrencyFlex (Input) by Karl Ermatinger
//
// Produces an English formatted dollar currency number with unlimited decimals but a least two decimals.
// Useful to display properly formatted commodity unit pricing involving fractions of pennies and trailing zeros.
//
// None of FileMaker’s current formatting options can produce or display this format.
// FileMaker requires you to either select a fixed decimal precision or if no precision then it won’t display trailing input zeros.
// So if field value is 1.10 or 1.100 etc, then unfortunately FileMaker will only display 1.1.
//
// Extraneous text is filtered out.
// Negative input numbers are maintained.
// 
// You MUST configure the FileMaker field display option of "As Entered" or else the custom fuction formatting will not show.
//
// Inspiration from "AddDollarFormat ( Number )" by Jeremiah Small of Soliant Consulting.
// Thanks also to “MB, Holland” for pointing out the NumToJText funtion to simplify integer formatting.
// Special thanks to Brian Dunning for this website.
//

Let ( [

FilteredNumber = Filter ( Input ; "-.0123456789" ) ;

DecimalRaw = Case(
     PatternCount ( FilteredNumber ; "." ) = 0; "00" ;
     Filter ( Right( FilteredNumber ; Length ( FilteredNumber ) - Position( FilteredNumber ; "." ; 1 ; 1 ) ) ; "0123456789")          // keep only numbers in the decimal portion
     ) ;

DecimalFinal = Case ( 
     Length( DecimalRaw ) = 0; "00";
     Length( DecimalRaw ) = 1; DecimalRaw & "0";
     DecimalRaw            // allow more than two decimals and keep trailing zeros
     ) ;

Integer = Case( IsEmpty( Int ( Abs (FilteredNumber ) ) ) ; "0" ; Int ( Abs (FilteredNumber ) ) )

] ;

Case ( 
IsEmpty ( FilteredNumber) ; "" ;          // leave an empty field as it is
PatternCount ( FilteredNumber ; "." ) > 1 ; "?" ;          // replace number with question mark if multiple decimals

// now build formatted number
"$"          // substitute desired currency symbol

& Case ( PatternCount ( FilteredNumber ; "-" ) > 0 ; "-" )          // maintain negative number symbol

& NumToJText ( Integer ; 1 ; 0)          // create formatted integer

& "."           // add decimal point

& DecimalFinal          // add formatted decimal

)          // end the case statement that was testing for an empty field and for multiple decimal symbols

)          // end the let statement

This custom function produces a dollar currency formatted number with a dot decimal symbol and displays at least two or more decimals while maintaining trailing zeros. This is useful for displaying formatted commodity unit pricing that may involve fractions of pennies and/or trailing zeros. It doesn’t require you to pre-define the decimal precision but rather flexes the precision along with that of the Input value, thus the name CurrencyFlex.

FileMaker has no native way accomplish this and will either force you to select a fixed decimal precision or will strip off trailing zeros and not provide the minimum two decimals in traditional currency format.

Extraneous text is filtered out. Negative input numbers are maintained.

NOTE: You MUST configure the FileMaker field display option of "As Entered" or else the custom function formatting will not show.

This custom function was inspired from the "AddDollarFormat ( Number )" by Jeremiah Small of Soliant Consulting. Thanks also to “MB, Holland” for pointing out the NumToJText function to simplify integer formatting. Special thanks to Brian Dunning for this website.

Jan 10, 2017 KE - fixed issue when the input number field was blank.

Feb 9, 2017 KE - changed function parameter name from Number to Input to indicate any mixed number and text values are allowed. Implemented use of NumToJText function to greatly simplify integer formatting.

Comments

		MB, Holland Feb 8, 2017
please look at: http://www.briandunning.com/cf/945 that function makes very smart use of the native numtojtext() funtion.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CurrencyFlex ( Input )

Comments

Support this website.

Support this website.