PathMaker ( thePath ; theFile ; pathSeparator )

Returns a properly formatted folder and/or file path by processing and combining thePath, theFile, and pathSeparator.

Average rating: 4.8 (12 votes) Log in to vote

Lewis Lorenz - Show more from this author
Lorenz Companies
http://www.LorenzCom.com

Sample input:

PathMaker ( "Macintosh HD2:Users/user/Documents:" ; "" ; "" )
PathMaker ( Get ( DocumentsPath ) ; "" ; ":" )
PathMaker ( Get ( DocumentsPath ) & "My Folder" ; "Untitled:/1.txt" ; "" )
PathMaker ( "file:" & Get ( DocumentsPath ) ; "Invoice.pdf" ; "" )
PathMaker ( Get ( DocumentsPath ) & "My Folder:Brochures:" ; "Untitled1.pdf" ; "" )
PathMaker ( Get ( DocumentsPath ) & "My Folder:Brochures:" ; "Untitled1.pdf" ; "\\" )

Sample output:

:Macintosh HD2:Users:user:Documents:
:Macintosh HD2:Users:user:Documents:
/Macintosh HD2/Users/user/Documents/My Folder/Untitled__1.txt
file:/Macintosh HD2/Users/user/Documents/Invoice.pdf
/Macintosh HD2/Users/user/Documents/My Folder/Brochures/Untitled1.pdf
\Macintosh HD2\Users\user\Documents\My Folder\Brochures\Untitled1.pdf

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [ 
//PATH: Default to NULL if thePath is empty.
p =  If ( IsEmpty ( Trim ( thePath ) ) ; "" ; thePath ) ;

//FM PREFIX: Preserve file reference prefix.
frp = Middle ( p ; 1 ; Position ( p ; ":" ; 1 ; 1 ) ) ;
frn = GetAsBoolean ( PatternCount ( "xfile:xfilemac:xfilewin:xfmnet:" ; "x" & Trim ( frp ) ) ) ;
p = If ( frn ; Replace ( p ; 1 ; Length ( frp ) ; "" ) ; p ) ;

//SYSTEM PLATFORM. -1 = OS 9, 1 = OSX, -2 = WIndows.
sp = Abs ( Get ( SystemPlatform ) ) ;

//PATH SEPARATOR: Guess path separator based on platform.
ps = Left ( If ( sp = 1 ; Filter ( p ; ":/\\" ) ; Filter ( p ; "\/" ) ) ; 1 ) ;  //Precedence importaant.
ps = If ( IsEmpty ( ps ) ; "/" ; ps ) ;
//Insure pathSeparator is a valid character before substituting path separators.
s = Left ( Filter ( pathSeparator ; "/:\\" ) ; 1 ) ;
//If invalid, use the separator guessed from the sent path.
s = If ( IsEmpty ( s ) ; ps ; s ) ; 
//Set all path separators to the proper value.
p = Substitute ( If ( sp = 1 ; Substitute ( p ; [ ":" ; s ] ) ; p ) ; [ "/" ; s ]  ; [ "\\" ; s ] ) ;

//Add path separator to the right if it does not exist.
p = p & If ( IsEmpty ( p ) or Right ( p ; 1 ) = s ; "" ; s ) ;

//PATH LIST: Separate path to a list.
pl = Substitute ( p ; s ; "¶" ) ;

//PATH STRING.
p = Substitute ( MiddleValues ( pl ; 1 ; ValueCount ( pl ) ) ; "¶" ; s ) ;
//Prepend file reference prefix and add the separator to the left if it does not exist.
p = If ( frn ; frp  ; "" ) & If ( IsEmpty ( p ) or Left ( p ; 1 ) = s ; "" ; s ) & p ;

//Replace path separators from file name, if it exists, with a "_".
f = Substitute ( theFile ; [ ":" ; "_" ] ; [ "/" ; "_" ]  ; [ "\\" ; "_" ] )
] ;

If ( pathSeparator = "?" ; "PathMaker ( thePath , theFile , pathSeparator[:/\] )" ; p & f )  //Send back the made path.

)
/* PathMaker ( thePath ; theFile ; pathSeparator )

Returns a properly formatted folder and/or file path by processing and combining thePath, theFile and pathSeparator.

    Easily change path separator in thePath.
    Preserves FileMaker Pro file reference prefixes (file:, filemac:, and filewin:).
    Conforms different separators in thePath to one only.
    Replaces errant separators in theFile with underscores.
    Separator defaults to the first path separator in thePath or to the system path separator if pathSeparator is blank.
    Concatenates thePath and theFile into a properly formatted file path.
    Use with the PathParser custom function for added path formatting control.

Parameters

    thePath - A folder path.
    theFile - A file name to append to thePath.
    pathSeparator - The separator used to separate folders in the thePath: /:\. If left blank the first found separator in thePath is used.

Examples

    PathMaker ( "Macintosh HD2:Users/user/Documents:" ; "" ; "" ) = :Macintosh HD2:Users:user:Documents:
    PathMaker ( Get ( DocumentsPath ) ; "" ; ":" ) = :Macintosh HD2:Users:user:Documents:
    PathMaker ( Get ( DocumentsPath ) & "My Folder" ; "Untitled:/1.txt" ; "" ) = /Macintosh HD2/Users/user/Documents/My Folder/Untitled__1.txt
    PathMaker ( "file:" & Get ( DocumentsPath ) ; "Invoice.pdf" ; "" ) = file:/Macintosh HD2/Users/user/Documents/Invoice.pdf
    PathMaker ( Get ( DocumentsPath ) & "My Folder:Brochures:" ; "Untitled1.pdf" ; "" ) = /Macintosh HD2/Users/user/Documents/My Folder/Brochures/Untitled1.pdf
    PathMaker ( Get ( DocumentsPath ) & "My Folder:Brochures:" ; "Untitled1.pdf" ; "\\" ) = \Macintosh HD2\Users\user\Documents\My Folder\Brochures\Untitled1.pdf
*/

PathMaker ( thePath , theFile , pathSeparator )

Returns a properly formatted folder and/or file path by processing and combining thePath, theFile and pathSeparator.

Easily change path separator in thePath.
Preserves FileMaker Pro file reference prefixes (file:, filemac:, and filewin:).
Conforms different separators in thePath to one only.
Replaces errant separators in theFile with underscores.
Separator defaults to the first path separator in thePath or to the system path separator if pathSeparator is blank.
Concatenates thePath and theFile into a properly formatted file path.
Use with the PathParser custom function for added path formatting control.

Parameters

thePath - A folder path.
theFile - A file name to append to thePath.
pathSeparator - The separator used to separate folders in the thePath: /:\. If left blank the first found separator in thePath is used.

Examples

PathMaker ( "Macintosh HD2:Users/user/Documents:" ; "" ; "" ) = :Macintosh HD2:Users:user:Documents:
PathMaker ( Get ( DocumentsPath ) ; "" ; ":" ) = :Macintosh HD2:Users:user:Documents:
PathMaker ( Get ( DocumentsPath ) & "My Folder" ; "Untitled:/1.txt" ; "" ) = /Macintosh HD2/Users/user/Documents/My Folder/Untitled__1.txt
PathMaker ( "file:" & Get ( DocumentsPath ) ; "Invoice.pdf" ; "" ) = file:/Macintosh HD2/Users/user/Documents/Invoice.pdf
PathMaker ( Get ( DocumentsPath ) & "My Folder:Brochures:" ; "Untitled1.pdf" ; "" ) = /Macintosh HD2/Users/user/Documents/My Folder/Brochures/Untitled1.pdf
PathMaker ( Get ( DocumentsPath ) & "My Folder:Brochures:" ; "Untitled1.pdf" ; "\\" ) = \Macintosh HD2\Users\user\Documents\My Folder\Brochures\Untitled1.pdf

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

PathMaker ( thePath ; theFile ; pathSeparator )

Comments

Support this website.

Support this website.