ValueListFilter ( pList ; pString ; pDir ; pPos ; pType )

Checks any valuelist for the occurrence of pString.

Average rating: 4.2 (30 votes) Log in to vote

Peter Schmidt
-/-
-/-

Sample input:

pList = "ID_usr¶forID_01¶forID_02¶
forID_03¶UserName¶
UserRolleName¶UserPasswort¶
GUserName¶gUserPasswort¶
gUserRolleName¶"

Sample output:

cfValueListFilter ( pList ; "g" ; 1 ; "" ; 1 ) = "gUserPasswort¶gUserRolleName¶"
cfValueListFilter ( pList ; "g" ; 1 ; "" ; 2 ) = "ID_usr¶forID_01¶forID_02¶forID_03¶UserName¶UserRolleName¶UserPasswort¶GUserName¶"
cfValueListFilter ( pList ; "Name" ; 2 ; "" ; 1 ) = "UserName¶UserRolleName¶GUserName¶gUserRolleName¶"
cfValueListFilter ( pList ; "Name" ; 2 ; "" ; 2 ) = "ID_usr¶forID_01¶forID_02¶forID_03¶UserPasswort¶gUserPasswort¶"
cfValueListFilter ( pList ; "ID" ; 3 ; 1 ; 1 ) = "ID_usr¶"
cfValueListFilter ( pList ; "ID" ; 3 ; 4 ; 1 ) = "forID_01¶forID_02¶forID_03¶"
cfValueListFilter ( pList ; "ID" ; 3 ; 4 ; 2 ) = "ID_usr¶UserName¶UserRolleName¶UserPasswort¶GUserName¶gUserPasswort¶gUserRolleName¶"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*===============

ValueListFilter

Author: Peter Schmidt
Date: 30.05.2012

Description:
Checks any valuelist for the occurrence of pString and displays only the values, which contains (pType = 1) or not contains (pType = 2) pString. Checking occurs from left (pDir = 1), right (pDir = 2) or middle (pDir = 3) and it's case-sensitive.

Function: cfValueListFilter ( pList ; pString ; pDir ; pPos ; pType )

--------------------*/

Let ( [ 

vCnt = ValueCount ( pList ) ; 
vVal = LeftValues ( pList ; 1 ) ; 
vLen1 = Length ( pString ) ; 
vLen2 = Length ( vVal ) ; 
vPos = If ( IsEmpty ( pPos ) ; 1 ; pPos ) ;
vText = Case (
	pDir = 1 ; Left ( vVal ; vLen1 ) ; 
	pDir = 2 ; Middle ( vVal ; vLen2 - vLen1 ; vLen1 ) ; 
	pDir = 3 ; Middle ( vVal ; vPos ; vLen1 ) ; 
	"" ) ;
vNew = Case (
	pType = 1 and Exact ( pString ; vText ) = 1 ; vVal ;
	pType = 2 and Exact ( pString ; vText ) = 0 ; vVal ;
	"" )

] ;	//  End Variables

If (
vCnt > 0 ; 
vNew & cfValueListFilter ( RightValues ( pList ; vCnt - 1 ) ; pString ; pDir ; pPos ; pType ) ; 
vNew )

)	//  End Let

/*--------------------

Parameter:
pList = Valuelist
pString = String to check
pDir = Search direction (1 = left / 2 = right / 3 = middle)
pPos = Position, to search from  (only pDir = 3)
pType = Type of output (1 = Only values, which contains pString / 2 = Only values, which not contains pString)

Result: Text

Example:
pList = "ID_usr¶forID_01¶forID_02¶forID_03¶UserName¶UserRolleName¶UserPasswort¶GUserName¶gUserPasswort¶gUserRolleName¶"
cfValueListFilter ( pList ; "g" ; 1 ; "" ; 1 ) = "gUserPasswort¶gUserRolleName¶"
cfValueListFilter ( pList ; "g" ; 1 ; "" ; 2 ) = "ID_usr¶forID_01¶forID_02¶forID_03¶UserName¶UserRolleName¶UserPasswort¶GUserName¶"
cfValueListFilter ( pList ; "Name" ; 2 ; "" ; 1 ) = "UserName¶UserRolleName¶GUserName¶gUserRolleName¶"
cfValueListFilter ( pList ; "Name" ; 2 ; "" ; 2 ) = "ID_usr¶forID_01¶forID_02¶forID_03¶UserPasswort¶gUserPasswort¶"
cfValueListFilter ( pList ; "ID" ; 3 ; 1 ; 1 ) = "ID_usr¶"
cfValueListFilter ( pList ; "ID" ; 3 ; 4 ; 1 ) = "forID_01¶forID_02¶forID_03¶"
cfValueListFilter ( pList ; "ID" ; 3 ; 4 ; 2 ) = "ID_usr¶UserName¶UserRolleName¶UserPasswort¶GUserName¶gUserPasswort¶gUserRolleName¶"

===============*/

Checks any valuelist for the occurrence of pString and displays only the values, which contains (pType = 1) or not contains (pType = 2) pString. Checking occurs from left (pDir = 1), right (pDir = 2) or middle (pDir = 3) and it's case-sensitive.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValueListFilter ( pList ; pString ; pDir ; pPos ; pType )

Comments

Support this website.

Support this website.