RandomStandardNormal

Returns random values from the Standard Normal distribution

Average rating: 4.9 (28 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

List (
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal;
RandomStandardNormal
)

Sample output:

1.41073264267008954613
-1.06287261458087525206
1.18226332551437196569
1.17248409573849158254
.44625235292511570306
-.83852348552055913166
.58817557434873573743
.68408067748026104281
1.09879428082311429906
-.34097400226953125095

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * RandomStandardNormal
 *
 * PURPOSE:
 * 		When called repeatedly, RandomStandardNormal creates values consistent
 *		with a normally distributed random variable with mean of 0 and standard
 *		deviation of 1.
 *
 * RETURNS:
 *		A number representing a random variate from the standard normal
 *		distribution.
 *
 * PARAMETERS: none
 *
 * VARIABLES:
 *		$$~STANDARDNORMAL: Saves the extra value from the sampling method for
 *		future reference as a performance improvement.
 *
 * DEPENDENCIES: none
 *
 * HISTORY:
 *		MODIFIED on 2011-02-22 by Jeremy Bante to store the Marsaglia polar
 *		method's extra value for later use.
 *		CREATED on 2010-02-22 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		http://en.wikipedia.org/wiki/Normal_distribution
 * =====================================
 */

If ( not IsEmpty ( $$~STANDARDNORMAL );
	//Use duplicate value from previous use of function
	$$~STANDARDNORMAL
	& Let ( $$~STANDARDNORMAL = "" ; "" );

	//Else, find new value with Marsaglia polar sampling method
	Let( [
		~x = Random * 2 - 1; //begin with random points
		~y = Random * 2 - 1;
		~radiusSquared = ~x ^ 2 + ~y ^ 2
	];

		Case (
			~radiusSquared < 1; //(~x, ~y) is inside the unit circle
				~x //return value
				* sqrt ( -2 * ln ( ~radiusSquared ) / ~radiusSquared )
				& Let (
					$$~STANDARDNORMAL = //save extra value
						~y
						* sqrt ( -2 * ln ( ~radiusSquared ) / ~radiusSquared );
					""
				);

			//Else, reject guess and sample again
				RandomStandardNormal
		)
	)
)

When called repeatedly, RandomStandardNormal creates values consistent with a normally distributed random variable with mean of 0 and standard deviation of 1.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

RandomStandardNormal

Comments

Support this website.

Support this website.