interpolate ( x ; y ; t ; 0 ; 0 )

Polynomial interpolation of arbitrary degree

Average rating: 4.5 (36 votes) Log in to vote

Wilhelm Werner - Show more from this author

Sample input:

interpolate("1¶2¶4¶8";"1¶2¶3¶4"; 3,24;0;0)

Sample output:

2,739370666666666667

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//interpolate ( x ; y ; t ; r ; s )
//
// Call: interpolate (x;y;t;0;0)
// 
// Arguments:
// x: list of nodes; arbritrary length
// y: values at nodes; same length as x
// t: interpolating polynomial is evaluated at t
// r,s are for internal use only
// 
// Implementation of Neville's algorithm
// http://en.wikipedia.org/wiki/Neville's_algorithm
//

Let(
    [
        prec = 36;
        n = ValueCount( x );
        xList = LeftValues( x; n );
        yList = LeftValues( y; n );
        i = If( r = 0 and s = 0; 1; r );
        k = If( r = 0 and s = 0; 2; s );
        old = yList;
        y1 = GetValue( yList; i );
        y2 = GetValue( yList; i + 1 );
        x1 = GetValue( xList; i );
        x2 = GetValue( xList; k );
        newval =
        SetPrecision( y1 + ( y2 - y1 ) / ( x2 - x1 ) * ( t - x1 ); prec );
        new = LeftValues( yList; i - 1 ) & newval & "¶" &
        RightValues( yList; n - i )
    ];
    If(
        k <= n;
        If(
            i > 0;
            interpolate( xList; new; t; i - 1; k );
            interpolate( xList; old; t; k; k + 1 )
        );
        Round( GetValue( new; 1 ); prec / 2 )
    )
)

Custom function implementation of Neville's algorithm for polynomial interpolation; see http://en.wikipedia.org/wiki/Neville's_algorithm .
The degree of the interpolating polynomial is determined by the length of the lists x resp. y; if ValueCount(x)=n then the degree is n-1.
The sample output above therefore is the value of the third degree interpolating polynomial at t=3,24.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

interpolate ( x ; y ; t ; 0 ; 0 )

Comments

Support this website.

Support this website.