FileMaker Pro Custom Functions

There's no need for recursion for this function. This does it in a single line of code:

Substitute ( "mouse¶rabbit¶lynx¶snake" ; ["rabbit";""] ; ["¶¶";"¶"] )

F. Osman Cabi, Turkey
June 09, 2010 2:43pm

I like the non-recursive one line solution suggested in the comment above, but it may remove parts of a value, not the whole value.

Example: Substitute ( "mouse¶rabbit¶lynx¶snake¶jackrabbit" ; ["rabbit";""] ; ["¶¶";"¶"] ) results in
"mouse¶lynx¶snake¶jack"

Adding the usual "¶" at the beginning and end of the ValueList and at the beginning and end of Value helps, but there may still be leftover returns depending on what the original list looked like. Rather than reinventing the wheel for dealing with extraneous "¶", I used the excellent CullNulls CF to do the cleanup and ended up with the following:

CullNulls( Substitute ( ¶ & ValueList & ¶ ; ¶ & Value & ¶ ; ¶ ) )

Note that unlike the original function presented, using CullNulls will remove leading/trailing returns originally in ValueList, so if retaining leading/trailing returns is important, additional logic is needed.

Cynthia, USA
June 16, 2010 4:52pm

Here's an edit to the code that removes the trailing return by using the List function instead of an '& "¶"' Also converted If statements to Case statements for brevity.


/*
RemoveValue custom function by Caleb Ruth, Data Performance LLC
Edited by Carter Brooks, developer.carterbrooks.com. Converted to use List function to remove trailing return

parameters:
Value
ValueList
*/


Let ( [
the_value_count = ValueCount ( ValueList ) ;
the_existing_value = GetValue ( ValueList ; 1 )
]
;

Case (
the_value_count > 0 ;

List(
Case (
not Exact ( Value ; the_existing_value ) ;
the_existing_value
)
;
RemoveValue ( Value ; RightValues ( ValueList ; the_value_count - 1 ) )
)
)

) //let

Carter Brooks, San Francisco
January 16, 2012 7:56pm

Here's a succinct non-rescursive function that neither adds nor removes leading or trailing line returns, only removes entire values (no partial line issues). It adds its own line returns to make the substitute work, and so knows it can remove them before returning the new list:


// ValueRemove ( valueList; itemValue )
// version 1.0, Daniel A. Shockley

Let(
cleanedListPadded = Substitute( "¶" & valueList & "¶"; "¶" & itemValue & "¶"; "¶")
; Middle( cleanedListPadded; 2; Length( cleanedListPadded ) - 2 )
)

Daniel A. Shockley, New York, NY
January 27, 2012 7:20am